· 9 years ago · Jan 18, 2017, 11:18 AM
1# Filename: /etc/zsh/zshrc
2# Purpose: config file for zsh (z shell)
3# Authors: grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
4# Bug-Reports: see http://grml.org/bugs/
5# License: This file is licensed under the GPL v2.
6################################################################################
7# This file is sourced only for interactive shells. It
8# should contain commands to set up aliases, functions,
9# options, key bindings, etc.
10#
11# Global Order: zshenv, zprofile, zshrc, zlogin
12################################################################################
13
14# USAGE
15# If you are using this file as your ~/.zshrc file, please use ~/.zshrc.pre
16# and ~/.zshrc.local for your own customisations. The former file is read
17# before ~/.zshrc, the latter is read after it. Also, consider reading the
18# refcard and the reference manual for this setup, both available from:
19# <http://grml.org/zsh/>
20
21# Contributing:
22# If you want to help to improve grml's zsh setup, clone the grml-etc-core
23# repository from git.grml.org:
24# git clone git://git.grml.org/grml-etc-core.git
25#
26# Make your changes, commit them; use 'git format-patch' to create a series
27# of patches and send those to the following address via 'git send-email':
28# grml-etc-core@grml.org
29#
30# Doing so makes sure the right people get your patches for review and
31# possibly inclusion.
32
33# zsh-refcard-tag documentation:
34# You may notice strange looking comments in this file.
35# These are there for a purpose. grml's zsh-refcard can now be
36# automatically generated from the contents of the actual configuration
37# file. However, we need a little extra information on which comments
38# and what lines of code to take into account (and for what purpose).
39#
40# Here is what they mean:
41#
42# List of tags (comment types) used:
43# #a# Next line contains an important alias, that should
44# be included in the grml-zsh-refcard.
45# (placement tag: @@INSERT-aliases@@)
46# #f# Next line contains the beginning of an important function.
47# (placement tag: @@INSERT-functions@@)
48# #v# Next line contains an important variable.
49# (placement tag: @@INSERT-variables@@)
50# #k# Next line contains an important keybinding.
51# (placement tag: @@INSERT-keybindings@@)
52# #d# Hashed directories list generation:
53# start denotes the start of a list of 'hash -d'
54# definitions.
55# end denotes its end.
56# (placement tag: @@INSERT-hasheddirs@@)
57# #A# Abbreviation expansion list generation:
58# start denotes the beginning of abbreviations.
59# end denotes their end.
60# Lines within this section that end in '#d .*' provide
61# extra documentation to be included in the refcard.
62# (placement tag: @@INSERT-abbrev@@)
63# #m# This tag allows you to manually generate refcard entries
64# for code lines that are hard/impossible to parse.
65# Example:
66# #m# k ESC-h Call the run-help function
67# That would add a refcard entry in the keybindings table
68# for 'ESC-h' with the given comment.
69# So the syntax is: #m# <section> <argument> <comment>
70# #o# This tag lets you insert entries to the 'other' hash.
71# Generally, this should not be used. It is there for
72# things that cannot be done easily in another way.
73# (placement tag: @@INSERT-other-foobar@@)
74#
75# All of these tags (except for m and o) take two arguments, the first
76# within the tag, the other after the tag:
77#
78# #<tag><section># <comment>
79#
80# Where <section> is really just a number, which are defined by the
81# @secmap array on top of 'genrefcard.pl'. The reason for numbers
82# instead of names is, that for the reader, the tag should not differ
83# much from a regular comment. For zsh, it is a regular comment indeed.
84# The numbers have got the following meanings:
85# 0 -> "default"
86# 1 -> "system"
87# 2 -> "user"
88# 3 -> "debian"
89# 4 -> "search"
90# 5 -> "shortcuts"
91# 6 -> "services"
92#
93# So, the following will add an entry to the 'functions' table in the
94# 'system' section, with a (hopefully) descriptive comment:
95# #f1# Edit an alias via zle
96# edalias() {
97#
98# It will then show up in the @@INSERT-aliases-system@@ replacement tag
99# that can be found in 'grml-zsh-refcard.tex.in'.
100# If the section number is omitted, the 'default' section is assumed.
101# Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
102# exactly the same as @@INSERT-aliases-default@@. If you want a list of
103# *all* aliases, for example, use @@INSERT-aliases-all@@.
104
105# zsh profiling
106# just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
107if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
108 zmodload zsh/zprof
109fi
110
111# load .zshrc.pre to give the user the chance to overwrite the defaults
112[[ -r ${ZDOTDIR:-${HOME}}/.zshrc.pre ]] && source ${ZDOTDIR:-${HOME}}/.zshrc.pre
113
114# check for version/system
115# check for versions (compatibility reasons)
116is4(){
117 [[ $ZSH_VERSION == <4->* ]] && return 0
118 return 1
119}
120
121is41(){
122 [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
123 return 1
124}
125
126is42(){
127 [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
128 return 1
129}
130
131is425(){
132 [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
133 return 1
134}
135
136is43(){
137 [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
138 return 1
139}
140
141is433(){
142 [[ $ZSH_VERSION == 4.3.<3->* || $ZSH_VERSION == 4.<4->* \
143 || $ZSH_VERSION == <5->* ]] && return 0
144 return 1
145}
146
147is437(){
148 [[ $ZSH_VERSION == 4.3.<7->* || $ZSH_VERSION == 4.<4->* \
149 || $ZSH_VERSION == <5->* ]] && return 0
150 return 1
151}
152
153is439(){
154 [[ $ZSH_VERSION == 4.3.<9->* || $ZSH_VERSION == 4.<4->* \
155 || $ZSH_VERSION == <5->* ]] && return 0
156 return 1
157}
158
159#f1# Checks whether or not you're running grml
160isgrml(){
161 [[ -f /etc/grml_version ]] && return 0
162 return 1
163}
164
165#f1# Checks whether or not you're running a grml cd
166isgrmlcd(){
167 [[ -f /etc/grml_cd ]] && return 0
168 return 1
169}
170
171if isgrml ; then
172#f1# Checks whether or not you're running grml-small
173 isgrmlsmall() {
174 if [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]]; then
175 return 0
176 fi
177 return 1
178 }
179else
180 isgrmlsmall() { return 1 }
181fi
182
183isdarwin(){
184 [[ $OSTYPE == darwin* ]] && return 0
185 return 1
186}
187
188isfreebsd(){
189 [[ $OSTYPE == freebsd* ]] && return 0
190 return 1
191}
192
193#f1# are we running within an utf environment?
194isutfenv() {
195 case "$LANG $CHARSET $LANGUAGE" in
196 *utf*) return 0 ;;
197 *UTF*) return 0 ;;
198 *) return 1 ;;
199 esac
200}
201
202# check for user, if not running as root set $SUDO to sudo
203(( EUID != 0 )) && SUDO='sudo' || SUDO=''
204
205# change directory to home on first invocation of zsh
206# important for rungetty -> autologin
207# Thanks go to Bart Schaefer!
208isgrml && checkhome() {
209 if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
210 export ALREADY_DID_CD_HOME=$HOME
211 cd
212 fi
213}
214
215# check for zsh v3.1.7+
216
217if ! [[ ${ZSH_VERSION} == 3.1.<7->* \
218 || ${ZSH_VERSION} == 3.<2->.<->* \
219 || ${ZSH_VERSION} == <4->.<->* ]] ; then
220
221 printf '-!-\n'
222 printf '-!- In this configuration we try to make use of features, that only\n'
223 printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
224 printf '-!- used with a wide range of zsh versions, while using fairly\n'
225 printf '-!- advanced features in all supported versions.\n'
226 printf '-!-\n'
227 printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
228 printf '-!-\n'
229 printf '-!- While this *may* work, it might as well fail.\n'
230 printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
231 printf '-!-\n'
232 printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
233 printf '-!- If it does today, you'\''ve been lucky.\n'
234 printf '-!-\n'
235 printf '-!- Ye been warned!\n'
236 printf '-!-\n'
237
238 function zstyle() { : }
239fi
240
241# autoload wrapper - use this one instead of autoload directly
242# We need to define this function as early as this, because autoloading
243# 'is-at-least()' needs it.
244function zrcautoload() {
245 emulate -L zsh
246 setopt extended_glob
247 local fdir ffile
248 local -i ffound
249
250 ffile=$1
251 (( ffound = 0 ))
252 for fdir in ${fpath} ; do
253 [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
254 done
255
256 (( ffound == 0 )) && return 1
257 if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
258 autoload -U ${ffile} || return 1
259 else
260 autoload ${ffile} || return 1
261 fi
262 return 0
263}
264
265# Load is-at-least() for more precise version checks Note that this test will
266# *always* fail, if the is-at-least function could not be marked for
267# autoloading.
268zrcautoload is-at-least || is-at-least() { return 1 }
269
270# set some important options (as early as possible)
271
272# append history list to the history file; this is the default but we make sure
273# because it's required for share_history.
274setopt append_history
275
276# import new commands from the history file also in other zsh-session
277is4 && setopt share_history
278
279# save each command's beginning timestamp and the duration to the history file
280setopt extended_history
281
282# If a new command line being added to the history list duplicates an older
283# one, the older command is removed from the list
284is4 && setopt histignorealldups
285
286# remove command lines from the history list when the first character on the
287# line is a space
288setopt histignorespace
289
290# if a command is issued that can't be executed as a normal command, and the
291# command is the name of a directory, perform the cd command to that directory.
292setopt auto_cd
293
294# in order to use #, ~ and ^ for filename generation grep word
295# *~(*.gz|*.bz|*.bz2|*.zip|*.Z) -> searches for word not in compressed files
296# don't forget to quote '^', '~' and '#'!
297setopt extended_glob
298
299# display PID when suspending processes as well
300setopt longlistjobs
301
302# try to avoid the 'zsh: no matches found...'
303setopt nonomatch
304
305# report the status of backgrounds jobs immediately
306setopt notify
307
308# whenever a command completion is attempted, make sure the entire command path
309# is hashed first.
310setopt hash_list_all
311
312# not just at the end
313setopt completeinword
314
315# Don't send SIGHUP to background processes when the shell exits.
316setopt nohup
317
318# make cd push the old directory onto the directory stack.
319setopt auto_pushd
320
321# avoid "beep"ing
322setopt nobeep
323
324# don't push the same dir twice.
325setopt pushd_ignore_dups
326
327# * shouldn't match dotfiles. ever.
328setopt noglobdots
329
330# use zsh style word splitting
331setopt noshwordsplit
332
333# don't error out when unset parameters are used
334setopt unset
335
336# setting some default values
337NOCOR=${NOCOR:-0}
338NOMENU=${NOMENU:-0}
339NOPRECMD=${NOPRECMD:-0}
340COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
341GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
342BATTERY=${BATTERY:-0}
343GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
344ZSH_NO_DEFAULT_LOCALE=${ZSH_NO_DEFAULT_LOCALE:-0}
345
346typeset -ga ls_options
347typeset -ga grep_options
348if ls --help 2> /dev/null | grep -q GNU; then
349 ls_options=( --color=auto )
350elif [[ $OSTYPE == freebsd* ]]; then
351 ls_options=( -G )
352fi
353if grep --help 2> /dev/null | grep -q GNU || \
354 [[ $OSTYPE == freebsd* ]]; then
355 grep_options=( --color=auto )
356fi
357
358# utility functions
359# this function checks if a command exists and returns either true
360# or false. This avoids using 'which' and 'whence', which will
361# avoid problems with aliases for which on certain weird systems. :-)
362# Usage: check_com [-c|-g] word
363# -c only checks for external commands
364# -g does the usual tests and also checks for global aliases
365check_com() {
366 emulate -L zsh
367 local -i comonly gatoo
368
369 if [[ $1 == '-c' ]] ; then
370 (( comonly = 1 ))
371 shift
372 elif [[ $1 == '-g' ]] ; then
373 (( gatoo = 1 ))
374 else
375 (( comonly = 0 ))
376 (( gatoo = 0 ))
377 fi
378
379 if (( ${#argv} != 1 )) ; then
380 printf 'usage: check_com [-c] <command>\n' >&2
381 return 1
382 fi
383
384 if (( comonly > 0 )) ; then
385 [[ -n ${commands[$1]} ]] && return 0
386 return 1
387 fi
388
389 if [[ -n ${commands[$1]} ]] \
390 || [[ -n ${functions[$1]} ]] \
391 || [[ -n ${aliases[$1]} ]] \
392 || [[ -n ${reswords[(r)$1]} ]] ; then
393
394 return 0
395 fi
396
397 if (( gatoo > 0 )) && [[ -n ${galiases[$1]} ]] ; then
398 return 0
399 fi
400
401 return 1
402}
403
404# creates an alias and precedes the command with
405# sudo if $EUID is not zero.
406salias() {
407 emulate -L zsh
408 local only=0 ; local multi=0
409 local key val
410 while [[ $1 == -* ]] ; do
411 case $1 in
412 (-o) only=1 ;;
413 (-a) multi=1 ;;
414 (--) shift ; break ;;
415 (-h)
416 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
417 printf ' -h shows this help text.\n'
418 printf ' -a replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
419 printf ' be careful using this option.\n'
420 printf ' -o only sets an alias if a preceding sudo would be needed.\n'
421 return 0
422 ;;
423 (*) printf "unkown option: '%s'\n" "$1" ; return 1 ;;
424 esac
425 shift
426 done
427
428 if (( ${#argv} > 1 )) ; then
429 printf 'Too many arguments %s\n' "${#argv}"
430 return 1
431 fi
432
433 key="${1%%\=*}" ; val="${1#*\=}"
434 if (( EUID == 0 )) && (( only == 0 )); then
435 alias -- "${key}=${val}"
436 elif (( EUID > 0 )) ; then
437 (( multi > 0 )) && val="${val// ; / ; sudo }"
438 alias -- "${key}=sudo ${val}"
439 fi
440
441 return 0
442}
443
444# a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
445# usage: uprint foo
446# Where foo is the *name* of the parameter you want printed.
447# Note that foo is no typo; $foo would be wrong here!
448if ! is42 ; then
449 uprint () {
450 emulate -L zsh
451 local -a u
452 local w
453 local parameter=$1
454
455 if [[ -z ${parameter} ]] ; then
456 printf 'usage: uprint <parameter>\n'
457 return 1
458 fi
459
460 for w in ${(P)parameter} ; do
461 [[ -z ${(M)u:#$w} ]] && u=( $u $w )
462 done
463
464 builtin print -l $u
465 }
466fi
467
468# Check if we can read given files and source those we can.
469xsource() {
470 if (( ${#argv} < 1 )) ; then
471 printf 'usage: xsource FILE(s)...\n' >&2
472 return 1
473 fi
474
475 while (( ${#argv} > 0 )) ; do
476 [[ -r "$1" ]] && source "$1"
477 shift
478 done
479 return 0
480}
481
482# Check if we can read a given file and 'cat(1)' it.
483xcat() {
484 emulate -L zsh
485 if (( ${#argv} != 1 )) ; then
486 printf 'usage: xcat FILE\n' >&2
487 return 1
488 fi
489
490 [[ -r $1 ]] && cat $1
491 return 0
492}
493
494# Remove these functions again, they are of use only in these
495# setup files. This should be called at the end of .zshrc.
496xunfunction() {
497 emulate -L zsh
498 local -a funcs
499 funcs=(salias xcat xsource xunfunction zrcautoload zrcautozle)
500 for func in $funcs ; do
501 [[ -n ${functions[$func]} ]] \
502 && unfunction $func
503 done
504 return 0
505}
506
507# this allows us to stay in sync with grml's zshrc and put own
508# modifications in ~/.zshrc.local
509zrclocal() {
510 xsource "/etc/zsh/zshrc.local"
511 xsource "${ZDOTDIR:-${HOME}}/.zshrc.local"
512 return 0
513}
514
515# locale setup
516if (( ZSH_NO_DEFAULT_LOCALE == 0 )); then
517 xsource "/etc/default/locale"
518fi
519
520for var in LANG LC_ALL LC_MESSAGES ; do
521 [[ -n ${(P)var} ]] && export $var
522done
523
524xsource "/etc/sysconfig/keyboard"
525
526TZ=$(xcat /etc/timezone)
527
528# set some variables
529if check_com -c vim ; then
530#v#
531 export EDITOR=${EDITOR:-vim}
532else
533 export EDITOR=${EDITOR:-vi}
534fi
535
536#v#
537export PAGER=${PAGER:-less}
538
539#v#
540export MAIL=${MAIL:-/var/mail/$USER}
541
542# if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
543export SHELL='/bin/zsh'
544
545# color setup for ls:
546check_com -c dircolors && eval $(dircolors -b)
547# color setup for ls on OS X / FreeBSD:
548isdarwin && export CLICOLOR=1
549isfreebsd && export CLICOLOR=1
550
551# do MacPorts setup on darwin
552if isdarwin && [[ -d /opt/local ]]; then
553 # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
554 # zshenv.
555 PATH="/opt/local/bin:/opt/local/sbin:$PATH"
556 MANPATH="/opt/local/share/man:$MANPATH"
557fi
558# do Fink setup on darwin
559isdarwin && xsource /sw/bin/init.sh
560
561# load our function and completion directories
562for fdir in /usr/share/grml/zsh/completion /usr/share/grml/zsh/functions; do
563 fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
564 if [[ ${fdir} == '/usr/share/grml/zsh/functions' ]] ; then
565 for func in ${fdir}/**/[^_]*[^~](N.) ; do
566 zrcautoload ${func:t}
567 done
568 fi
569done
570unset fdir func
571
572# support colors in less
573export LESS_TERMCAP_mb=$'\E[01;31m'
574export LESS_TERMCAP_md=$'\E[01;31m'
575export LESS_TERMCAP_me=$'\E[0m'
576export LESS_TERMCAP_se=$'\E[0m'
577export LESS_TERMCAP_so=$'\E[01;44;33m'
578export LESS_TERMCAP_ue=$'\E[0m'
579export LESS_TERMCAP_us=$'\E[01;32m'
580
581# mailchecks
582MAILCHECK=30
583
584# report about cpu-/system-/user-time of command if running longer than
585# 5 seconds
586REPORTTIME=5
587
588# watch for everyone but me and root
589watch=(notme root)
590
591# automatically remove duplicates from these arrays
592typeset -U path cdpath fpath manpath
593
594# Load a few modules
595is4 && \
596for mod in parameter complist deltochar mathfunc ; do
597 zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
598done
599
600# autoload zsh modules when they are referenced
601if is4 ; then
602 zmodload -a zsh/stat zstat
603 zmodload -a zsh/zpty zpty
604 zmodload -ap zsh/mapfile mapfile
605fi
606
607# completion system
608if zrcautoload compinit ; then
609 compinit || print 'Notice: no compinit available :('
610else
611 print 'Notice: no compinit available :('
612 function compdef { }
613fi
614
615# completion system
616
617# called later (via is4 && grmlcomp)
618# note: use 'zstyle' for getting current settings
619# press ^xh (control-x h) for getting tags in context; ^x? (control-x ?) to run complete_debug with trace output
620grmlcomp() {
621 # TODO: This could use some additional information
622
623 # Make sure the completion system is initialised
624 (( ${+_comps} )) || return 1
625
626 # allow one error for every three characters typed in approximate completer
627 zstyle ':completion:*:approximate:' max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
628
629 # don't complete backup files as executables
630 zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
631
632 # start menu completion only if it could find no unambiguous initial string
633 zstyle ':completion:*:correct:*' insert-unambiguous true
634 zstyle ':completion:*:corrections' format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
635 zstyle ':completion:*:correct:*' original true
636
637 # activate color-completion
638 zstyle ':completion:*:default' list-colors ${(s.:.)LS_COLORS}
639
640 # format on completion
641 zstyle ':completion:*:descriptions' format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
642
643 # automatically complete 'cd -<tab>' and 'cd -<ctrl-d>' with menu
644 # zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
645
646 # insert all expansions for expand completer
647 zstyle ':completion:*:expand:*' tag-order all-expansions
648 zstyle ':completion:*:history-words' list false
649
650 # activate menu
651 zstyle ':completion:*:history-words' menu yes
652
653 # ignore duplicate entries
654 zstyle ':completion:*:history-words' remove-all-dups yes
655 zstyle ':completion:*:history-words' stop yes
656
657 # match uppercase from lowercase
658 zstyle ':completion:*' matcher-list 'm:{a-z}={A-Z}'
659
660 # separate matches into groups
661 zstyle ':completion:*:matches' group 'yes'
662 zstyle ':completion:*' group-name ''
663
664 if [[ "$NOMENU" -eq 0 ]] ; then
665 # if there are more than 5 options allow selecting from a menu
666 zstyle ':completion:*' menu select=5
667 else
668 # don't use any menus at all
669 setopt no_auto_menu
670 fi
671
672 zstyle ':completion:*:messages' format '%d'
673 zstyle ':completion:*:options' auto-description '%d'
674
675 # describe options in full
676 zstyle ':completion:*:options' description 'yes'
677
678 # on processes completion complete all user processes
679 zstyle ':completion:*:processes' command 'ps -au$USER'
680
681 # offer indexes before parameters in subscripts
682 zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
683
684 # provide verbose completion information
685 zstyle ':completion:*' verbose true
686
687 # recent (as of Dec 2007) zsh versions are able to provide descriptions
688 # for commands (read: 1st word in the line) that it will list for the user
689 # to choose from. The following disables that, because it's not exactly fast.
690 zstyle ':completion:*:-command-:*:' verbose false
691
692 # set format for warnings
693 zstyle ':completion:*:warnings' format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
694
695 # define files to ignore for zcompile
696 zstyle ':completion:*:*:zcompile:*' ignored-patterns '(*~|*.zwc)'
697 zstyle ':completion:correct:' prompt 'correct to: %e'
698
699 # Ignore completion functions for commands you don't have:
700 zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
701
702 # Provide more processes in completion of programs like killall:
703 zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
704
705 # complete manual by their section
706 zstyle ':completion:*:manuals' separate-sections true
707 zstyle ':completion:*:manuals.*' insert-sections true
708 zstyle ':completion:*:man:*' menu yes select
709
710 # Search path for sudo completion
711 zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
712 /usr/local/bin \
713 /usr/sbin \
714 /usr/bin \
715 /sbin \
716 /bin \
717 /usr/X11R6/bin
718
719 # provide .. as a completion
720 zstyle ':completion:*' special-dirs ..
721
722 # run rehash on completion so new installed program are found automatically:
723 _force_rehash() {
724 (( CURRENT == 1 )) && rehash
725 return 1
726 }
727
728 ## correction
729 # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
730 if [[ "$NOCOR" -gt 0 ]] ; then
731 zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
732 setopt nocorrect
733 else
734 # try to be smart about when to use what completer...
735 setopt correct
736 zstyle -e ':completion:*' completer '
737 if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
738 _last_try="$HISTNO$BUFFER$CURSOR"
739 reply=(_complete _match _ignored _prefix _files)
740 else
741 if [[ $words[1] == (rm|mv) ]] ; then
742 reply=(_complete _files)
743 else
744 reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
745 fi
746 fi'
747 fi
748
749 # command for process lists, the local web server details and host completion
750 zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
751
752 # caching
753 [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
754 zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
755
756 # host completion
757 if is42 ; then
758 [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
759 [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
760 else
761 _ssh_hosts=()
762 _etc_hosts=()
763 fi
764 hosts=(
765 $(hostname)
766 "$_ssh_hosts[@]"
767 "$_etc_hosts[@]"
768 localhost
769 )
770 zstyle ':completion:*:hosts' hosts $hosts
771 # TODO: so, why is this here?
772 # zstyle '*' hosts $hosts
773
774 # use generic completion system for programs not yet defined; (_gnu_generic works
775 # with commands that provide a --help option with "standard" gnu-like output.)
776 for compcom in cp deborphan df feh fetchipac head hnb ipacsum mv \
777 pal stow tail uname ; do
778 [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
779 done; unset compcom
780
781 # see upgrade function in this file
782 compdef _hosts upgrade
783}
784
785# Keyboard setup: The following is based on the same code, we wrote for
786# debian's setup. It ensures the terminal is in the right mode, when zle is
787# active, so the values from $terminfo are valid. Therefore, this setup should
788# work on all systems, that have support for `terminfo'. It also requires the
789# zsh in use to have the `zsh/terminfo' module built.
790#
791# If you are customising your `zle-line-init()' or `zle-line-finish()'
792# functions, make sure you call the following utility functions in there:
793#
794# - zle-line-init(): zle-smkx
795# - zle-line-finish(): zle-rmkx
796
797# Use emacs-like key bindings by default:
798bindkey -e
799
800# Custom widgets:
801
802## beginning-of-line OR beginning-of-buffer OR beginning of history
803## by: Bart Schaefer <schaefer@brasslantern.com>, Bernhard Tittelbach
804beginning-or-end-of-somewhere() {
805 local hno=$HISTNO
806 if [[ ( "${LBUFFER[-1]}" == $'\n' && "${WIDGET}" == beginning-of* ) || \
807 ( "${RBUFFER[1]}" == $'\n' && "${WIDGET}" == end-of* ) ]]; then
808 zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
809 else
810 zle .${WIDGET:s/somewhere/line-hist/} "$@"
811 if (( HISTNO != hno )); then
812 zle .${WIDGET:s/somewhere/buffer-or-history/} "$@"
813 fi
814 fi
815}
816zle -N beginning-of-somewhere beginning-or-end-of-somewhere
817zle -N end-of-somewhere beginning-or-end-of-somewhere
818
819## toggle the ,. abbreviation feature on/off
820# NOABBREVIATION: default abbreviation-state
821# 0 - enabled (default)
822# 1 - disabled
823NOABBREVIATION=${NOABBREVIATION:-0}
824
825grml_toggle_abbrev() {
826 if (( ${NOABBREVIATION} > 0 )) ; then
827 NOABBREVIATION=0
828 else
829 NOABBREVIATION=1
830 fi
831}
832zle -N grml_toggle_abbrev
833
834# add a command line to the shells history without executing it
835commit-to-history() {
836 print -s ${(z)BUFFER}
837 zle send-break
838}
839zle -N commit-to-history
840
841# only slash should be considered as a word separator:
842slash-backward-kill-word() {
843 local WORDCHARS="${WORDCHARS:s@/@}"
844 # zle backward-word
845 zle backward-kill-word
846}
847zle -N slash-backward-kill-word
848
849# a generic accept-line wrapper
850
851# This widget can prevent unwanted autocorrections from command-name
852# to _command-name, rehash automatically on enter and call any number
853# of builtin and user-defined widgets in different contexts.
854#
855# For a broader description, see:
856# <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
857#
858# The code is imported from the file 'zsh/functions/accept-line' from
859# <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
860# distributed under the same terms as zsh itself.
861
862# A newly added command will may not be found or will cause false
863# correction attempts, if you got auto-correction set. By setting the
864# following style, we force accept-line() to rehash, if it cannot
865# find the first word on the command line in the $command[] hash.
866zstyle ':acceptline:*' rehash true
867
868function Accept-Line() {
869 setopt localoptions noksharrays
870 local -a subs
871 local -xi aldone
872 local sub
873 local alcontext=${1:-$alcontext}
874
875 zstyle -a ":acceptline:${alcontext}" actions subs
876
877 (( ${#subs} < 1 )) && return 0
878
879 (( aldone = 0 ))
880 for sub in ${subs} ; do
881 [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
882 zle ${sub}
883
884 (( aldone > 0 )) && break
885 done
886}
887
888function Accept-Line-getdefault() {
889 emulate -L zsh
890 local default_action
891
892 zstyle -s ":acceptline:${alcontext}" default_action default_action
893 case ${default_action} in
894 ((accept-line|))
895 printf ".accept-line"
896 ;;
897 (*)
898 printf ${default_action}
899 ;;
900 esac
901}
902
903function Accept-Line-HandleContext() {
904 zle Accept-Line
905
906 default_action=$(Accept-Line-getdefault)
907 zstyle -T ":acceptline:${alcontext}" call_default \
908 && zle ${default_action}
909}
910
911function accept-line() {
912 setopt localoptions noksharrays
913 local -ax cmdline
914 local -x alcontext
915 local buf com fname format msg default_action
916
917 alcontext='default'
918 buf="${BUFFER}"
919 cmdline=(${(z)BUFFER})
920 com="${cmdline[1]}"
921 fname="_${com}"
922
923 Accept-Line 'preprocess'
924
925 zstyle -t ":acceptline:${alcontext}" rehash \
926 && [[ -z ${commands[$com]} ]] \
927 && rehash
928
929 if [[ -n ${com} ]] \
930 && [[ -n ${reswords[(r)$com]} ]] \
931 || [[ -n ${aliases[$com]} ]] \
932 || [[ -n ${functions[$com]} ]] \
933 || [[ -n ${builtins[$com]} ]] \
934 || [[ -n ${commands[$com]} ]] ; then
935
936 # there is something sensible to execute, just do it.
937 alcontext='normal'
938 Accept-Line-HandleContext
939
940 return
941 fi
942
943 if [[ -o correct ]] \
944 || [[ -o correctall ]] \
945 && [[ -n ${functions[$fname]} ]] ; then
946
947 # nothing there to execute but there is a function called
948 # _command_name; a completion widget. Makes no sense to
949 # call it on the commandline, but the correct{,all} options
950 # will ask for it nevertheless, so warn the user.
951 if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
952 # Okay, we warned the user before, he called us again,
953 # so have it his way.
954 alcontext='force'
955 Accept-Line-HandleContext
956
957 return
958 fi
959
960 if zstyle -t ":acceptline:${alcontext}" nocompwarn ; then
961 alcontext='normal'
962 Accept-Line-HandleContext
963 else
964 # prepare warning message for the user, configurable via zstyle.
965 zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
966
967 if [[ -z ${msg} ]] ; then
968 msg="%c will not execute and completion %f exists."
969 fi
970
971 zformat -f msg "${msg}" "c:${com}" "f:${fname}"
972
973 zle -M -- "${msg}"
974 fi
975 return
976 elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
977 # If we are here, the commandline contains something that is not
978 # executable, which is neither subject to _command_name correction
979 # and is not empty. might be a variable assignment
980 alcontext='misc'
981 Accept-Line-HandleContext
982
983 return
984 fi
985
986 # If we got this far, the commandline only contains whitespace, or is empty.
987 alcontext='empty'
988 Accept-Line-HandleContext
989}
990
991zle -N accept-line
992zle -N Accept-Line
993zle -N Accept-Line-HandleContext
994
995# power completion - abbreviation expansion
996# power completion / abbreviation expansion / buffer expansion
997# see http://zshwiki.org/home/examples/zleiab for details
998# less risky than the global aliases but powerful as well
999# just type the abbreviation key and afterwards ',.' to expand it
1000declare -A abk
1001setopt extendedglob
1002setopt interactivecomments
1003abk=(
1004# key # value (#d additional doc string)
1005#A# start
1006 '...' '../..'
1007 '....' '../../..'
1008 'BG' '& exit'
1009 'C' '| wc -l'
1010 'G' '|& grep '${grep_options:+"${grep_options[*]}"}
1011 'H' '| head'
1012 'Hl' ' --help |& less -r' #d (Display help in pager)
1013 'L' '| less'
1014 'LL' '|& less -r'
1015 'M' '| most'
1016 'N' '&>/dev/null' #d (No Output)
1017 'R' '| tr A-z N-za-m' #d (ROT13)
1018 'SL' '| sort | less'
1019 'S' '| sort -u'
1020 'T' '| tail'
1021 'V' '|& vim -'
1022#A# end
1023 'co' './configure && make && sudo make install'
1024)
1025
1026zleiab() {
1027 emulate -L zsh
1028 setopt extendedglob
1029 local MATCH
1030
1031 if (( NOABBREVIATION > 0 )) ; then
1032 LBUFFER="${LBUFFER},."
1033 return 0
1034 fi
1035
1036 LBUFFER=${LBUFFER%%(#m)[.\-+:|_a-zA-Z0-9]#}
1037 LBUFFER+=${abk[$MATCH]:-$MATCH}
1038}
1039
1040zle -N zleiab
1041
1042help-show-abk()
1043{
1044 zle -M "$(print "Type ,. after these abbreviations to expand them:"; print -a -C 2 ${(kv)abk})"
1045}
1046
1047zle -N help-show-abk
1048
1049# press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
1050insert-datestamp() { LBUFFER+=${(%):-'%D{%Y-%m-%d}'}; }
1051zle -N insert-datestamp
1052
1053# press esc-m for inserting last typed word again (thanks to caphuso!)
1054insert-last-typed-word() { zle insert-last-word -- 0 -1 };
1055zle -N insert-last-typed-word;
1056
1057function grml-zsh-fg() {
1058 if (( ${#jobstates} )); then
1059 zle .push-input
1060 [[ -o hist_ignore_space ]] && BUFFER=' ' || BUFFER=''
1061 BUFFER="${BUFFER}fg"
1062 zle .accept-line
1063 else
1064 zle -M 'No background jobs. Doing nothing.'
1065 fi
1066}
1067zle -N grml-zsh-fg
1068
1069# run command line as user root via sudo:
1070sudo-command-line() {
1071 [[ -z $BUFFER ]] && zle up-history
1072 if [[ $BUFFER != sudo\ * ]]; then
1073 BUFFER="sudo $BUFFER"
1074 CURSOR=$(( CURSOR+5 ))
1075 fi
1076}
1077zle -N sudo-command-line
1078
1079### jump behind the first word on the cmdline.
1080### useful to add options.
1081function jump_after_first_word() {
1082 local words
1083 words=(${(z)BUFFER})
1084
1085 if (( ${#words} <= 1 )) ; then
1086 CURSOR=${#BUFFER}
1087 else
1088 CURSOR=${#${words[1]}}
1089 fi
1090}
1091zle -N jump_after_first_word
1092
1093#f5# Create directory under cursor or the selected area
1094inplaceMkDirs() {
1095 # Press ctrl-xM to create the directory under the cursor or the selected area.
1096 # To select an area press ctrl-@ or ctrl-space and use the cursor.
1097 # Use case: you type "mv abc ~/testa/testb/testc/" and remember that the
1098 # directory does not exist yet -> press ctrl-XM and problem solved
1099 local PATHTOMKDIR
1100 if ((REGION_ACTIVE==1)); then
1101 local F=$MARK T=$CURSOR
1102 if [[ $F -gt $T ]]; then
1103 F=${CURSOR}
1104 T=${MARK}
1105 fi
1106 # get marked area from buffer and eliminate whitespace
1107 PATHTOMKDIR=${BUFFER[F+1,T]%%[[:space:]]##}
1108 PATHTOMKDIR=${PATHTOMKDIR##[[:space:]]##}
1109 else
1110 local bufwords iword
1111 bufwords=(${(z)LBUFFER})
1112 iword=${#bufwords}
1113 bufwords=(${(z)BUFFER})
1114 PATHTOMKDIR="${(Q)bufwords[iword]}"
1115 fi
1116 [[ -z "${PATHTOMKDIR}" ]] && return 1
1117 PATHTOMKDIR=${~PATHTOMKDIR}
1118 if [[ -e "${PATHTOMKDIR}" ]]; then
1119 zle -M " path already exists, doing nothing"
1120 else
1121 zle -M "$(mkdir -p -v "${PATHTOMKDIR}")"
1122 zle end-of-line
1123 fi
1124}
1125
1126#k# mkdir -p <dir> from string under cursor or marked area
1127zle -N inplaceMkDirs
1128
1129#v1# set number of lines to display per page
1130HELP_LINES_PER_PAGE=20
1131#v1# set location of help-zle cache file
1132HELP_ZLE_CACHE_FILE=~/.cache/zsh_help_zle_lines.zsh
1133# helper function for help-zle, actually generates the help text
1134help_zle_parse_keybindings()
1135{
1136 emulate -L zsh
1137 setopt extendedglob
1138 unsetopt ksharrays #indexing starts at 1
1139
1140 #v1# choose files that help-zle will parse for keybindings
1141 ((${+HELPZLE_KEYBINDING_FILES})) || HELPZLE_KEYBINDING_FILES=( /etc/zsh/zshrc ~/.zshrc.pre ~/.zshrc ~/.zshrc.local )
1142
1143 if [[ -r $HELP_ZLE_CACHE_FILE ]]; then
1144 local load_cache=0
1145 for f ($HELPZLE_KEYBINDING_FILES) [[ $f -nt $HELP_ZLE_CACHE_FILE ]] && load_cache=1
1146 [[ $load_cache -eq 0 ]] && . $HELP_ZLE_CACHE_FILE && return
1147 fi
1148
1149 #fill with default keybindings, possibly to be overwriten in a file later
1150 #Note that due to zsh inconsistency on escaping assoc array keys, we encase the key in '' which we will remove later
1151 local -A help_zle_keybindings
1152 help_zle_keybindings['<Ctrl>@']="set MARK"
1153 help_zle_keybindings['<Ctrl>x<Ctrl>j']="vi-join lines"
1154 help_zle_keybindings['<Ctrl>x<Ctrl>b']="jump to matching brace"
1155 help_zle_keybindings['<Ctrl>x<Ctrl>u']="undo"
1156 help_zle_keybindings['<Ctrl>_']="undo"
1157 help_zle_keybindings['<Ctrl>x<Ctrl>f<c>']="find <c> in cmdline"
1158 help_zle_keybindings['<Ctrl>a']="goto beginning of line"
1159 help_zle_keybindings['<Ctrl>e']="goto end of line"
1160 help_zle_keybindings['<Ctrl>t']="transpose charaters"
1161 help_zle_keybindings['<Alt>t']="transpose words"
1162 help_zle_keybindings['<Alt>s']="spellcheck word"
1163 help_zle_keybindings['<Ctrl>k']="backward kill buffer"
1164 help_zle_keybindings['<Ctrl>u']="forward kill buffer"
1165 help_zle_keybindings['<Ctrl>y']="insert previously killed word/string"
1166 help_zle_keybindings["<Alt>'"]="quote line"
1167 help_zle_keybindings['<Alt>"']="quote from mark to cursor"
1168 help_zle_keybindings['<Alt><arg>']="repeat next cmd/char <arg> times (<Alt>-<Alt>1<Alt>0a -> -10 times 'a')"
1169 help_zle_keybindings['<Alt>u']="make next word Uppercase"
1170 help_zle_keybindings['<Alt>l']="make next word lowercase"
1171 help_zle_keybindings['<Ctrl>xd']="preview expansion under cursor"
1172 help_zle_keybindings['<Alt>q']="push current CL into background, freeing it. Restore on next CL"
1173 help_zle_keybindings['<Alt>.']="insert (and interate through) last word from prev CLs"
1174 help_zle_keybindings['<Alt>,']="complete word from newer history (consecutive hits)"
1175 help_zle_keybindings['<Alt>m']="repeat last typed word on current CL"
1176 help_zle_keybindings['<Ctrl>v']="insert next keypress symbol literally (e.g. for bindkey)"
1177 help_zle_keybindings['!!:n*<Tab>']="insert last n arguments of last command"
1178 help_zle_keybindings['!!:n-<Tab>']="insert arguments n..N-2 of last command (e.g. mv s s d)"
1179 help_zle_keybindings['<Alt>h']="show help/manpage for current command"
1180
1181 #init global variables
1182 unset help_zle_lines help_zle_sln
1183 typeset -g -a help_zle_lines
1184 typeset -g help_zle_sln=1
1185
1186 local k v
1187 local lastkeybind_desc contents #last description starting with #k# that we found
1188 local num_lines_elapsed=0 #number of lines between last description and keybinding
1189 #search config files in the order they a called (and thus the order in which they overwrite keybindings)
1190 for f in $HELPZLE_KEYBINDING_FILES; do
1191 [[ -r "$f" ]] || continue #not readable ? skip it
1192 contents="$(<$f)"
1193 for cline in "${(f)contents}"; do
1194 #zsh pattern: matches lines like: #k# ..............
1195 if [[ "$cline" == (#s)[[:space:]]#\#k\#[[:space:]]##(#b)(*)[[:space:]]#(#e) ]]; then
1196 lastkeybind_desc="$match[*]"
1197 num_lines_elapsed=0
1198 #zsh pattern: matches lines that set a keybinding using bind2map, bindkey or compdef -k
1199 # ignores lines that are commentend out
1200 # grabs first in '' or "" enclosed string with length between 1 and 6 characters
1201 elif [[ "$cline" == [^#]#(bind2maps[[:space:]](*)-s|bindkey|compdef -k)[[:space:]](*)(#b)(\"((?)(#c1,6))\"|\'((?)(#c1,6))\')(#B)(*) ]]; then
1202 #description prevously found ? description not more than 2 lines away ? keybinding not empty ?
1203 if [[ -n $lastkeybind_desc && $num_lines_elapsed -lt 2 && -n $match[1] ]]; then
1204 #substitute keybinding string with something readable
1205 k=${${${${${${${match[1]/\\e\^h/<Alt><BS>}/\\e\^\?/<Alt><BS>}/\\e\[5~/<PageUp>}/\\e\[6~/<PageDown>}//(\\e|\^\[)/<Alt>}//\^/<Ctrl>}/3~/<Alt><Del>}
1206 #put keybinding in assoc array, possibly overwriting defaults or stuff found in earlier files
1207 #Note that we are extracting the keybinding-string including the quotes (see Note at beginning)
1208 help_zle_keybindings[${k}]=$lastkeybind_desc
1209 fi
1210 lastkeybind_desc=""
1211 else
1212 ((num_lines_elapsed++))
1213 fi
1214 done
1215 done
1216 unset contents
1217 #calculate length of keybinding column
1218 local kstrlen=0
1219 for k (${(k)help_zle_keybindings[@]}) ((kstrlen < ${#k})) && kstrlen=${#k}
1220 #convert the assoc array into preformated lines, which we are able to sort
1221 for k v in ${(kv)help_zle_keybindings[@]}; do
1222 #pad keybinding-string to kstrlen chars and remove outermost characters (i.e. the quotes)
1223 help_zle_lines+=("${(r:kstrlen:)k[2,-2]}${v}")
1224 done
1225 #sort lines alphabetically
1226 help_zle_lines=("${(i)help_zle_lines[@]}")
1227 [[ -d ${HELP_ZLE_CACHE_FILE:h} ]] || mkdir -p "${HELP_ZLE_CACHE_FILE:h}"
1228 echo "help_zle_lines=(${(q)help_zle_lines[@]})" >| $HELP_ZLE_CACHE_FILE
1229 zcompile $HELP_ZLE_CACHE_FILE
1230}
1231typeset -g help_zle_sln
1232typeset -g -a help_zle_lines
1233
1234# Provides (partially autogenerated) help on keybindings and the zsh line editor
1235help-zle()
1236{
1237 emulate -L zsh
1238 unsetopt ksharrays #indexing starts at 1
1239 #help lines already generated ? no ? then do it
1240 [[ ${+functions[help_zle_parse_keybindings]} -eq 1 ]] && {help_zle_parse_keybindings && unfunction help_zle_parse_keybindings}
1241 #already displayed all lines ? go back to the start
1242 [[ $help_zle_sln -gt ${#help_zle_lines} ]] && help_zle_sln=1
1243 local sln=$help_zle_sln
1244 #note that help_zle_sln is a global var, meaning we remember the last page we viewed
1245 help_zle_sln=$((help_zle_sln + HELP_LINES_PER_PAGE))
1246 zle -M "${(F)help_zle_lines[sln,help_zle_sln-1]}"
1247}
1248zle -N help-zle
1249
1250## complete word from currently visible Screen or Tmux buffer.
1251if check_com -c screen || check_com -c tmux; then
1252 _complete_screen_display() {
1253 [[ "$TERM" != "screen" ]] && return 1
1254
1255 local TMPFILE=$(mktemp)
1256 local -U -a _screen_display_wordlist
1257 trap "rm -f $TMPFILE" EXIT
1258
1259 # fill array with contents from screen hardcopy
1260 if ((${+TMUX})); then
1261 #works, but crashes tmux below version 1.4
1262 #luckily tmux -V option to ask for version, was also added in 1.4
1263 tmux -V &>/dev/null || return
1264 tmux -q capture-pane \; save-buffer -b 0 $TMPFILE \; delete-buffer -b 0
1265 else
1266 screen -X hardcopy $TMPFILE
1267 # screen sucks, it dumps in latin1, apparently always. so recode it
1268 # to system charset
1269 check_com recode && recode latin1 $TMPFILE
1270 fi
1271 _screen_display_wordlist=( ${(QQ)$(<$TMPFILE)} )
1272 # remove PREFIX to be completed from that array
1273 _screen_display_wordlist[${_screen_display_wordlist[(i)$PREFIX]}]=""
1274 compadd -a _screen_display_wordlist
1275 }
1276 #m# k CTRL-x\,\,\,S Complete word from GNU screen buffer
1277 bindkey -r "^xS"
1278 compdef -k _complete_screen_display complete-word '^xS'
1279fi
1280
1281# Load a few more functions and tie them to widgets, so they can be bound:
1282
1283function zrcautozle() {
1284 emulate -L zsh
1285 local fnc=$1
1286 zrcautoload $fnc && zle -N $fnc
1287}
1288
1289function zrcgotwidget() {
1290 (( ${+widgets[$1]} ))
1291}
1292
1293function zrcgotkeymap() {
1294 [[ -n ${(M)keymaps:#$1} ]]
1295}
1296
1297zrcautozle insert-files
1298zrcautozle edit-command-line
1299zrcautozle insert-unicode-char
1300if zrcautoload history-search-end; then
1301 zle -N history-beginning-search-backward-end history-search-end
1302 zle -N history-beginning-search-forward-end history-search-end
1303fi
1304zle -C hist-complete complete-word _generic
1305zstyle ':completion:hist-complete:*' completer _history
1306
1307# The actual terminal setup hooks and bindkey-calls:
1308
1309# An array to note missing features to ease diagnosis in case of problems.
1310typeset -ga grml_missing_features
1311
1312function zrcbindkey() {
1313 if (( ARGC )) && zrcgotwidget ${argv[-1]}; then
1314 bindkey "$@"
1315 fi
1316}
1317
1318function bind2maps () {
1319 local i sequence widget
1320 local -a maps
1321
1322 while [[ "$1" != "--" ]]; do
1323 maps+=( "$1" )
1324 shift
1325 done
1326 shift
1327
1328 if [[ "$1" == "-s" ]]; then
1329 shift
1330 sequence="$1"
1331 else
1332 sequence="${key[$1]}"
1333 fi
1334 widget="$2"
1335
1336 [[ -z "$sequence" ]] && return 1
1337
1338 for i in "${maps[@]}"; do
1339 zrcbindkey -M "$i" "$sequence" "$widget"
1340 done
1341}
1342
1343if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
1344 function zle-smkx () {
1345 emulate -L zsh
1346 printf '%s' ${terminfo[smkx]}
1347 }
1348 function zle-rmkx () {
1349 emulate -L zsh
1350 printf '%s' ${terminfo[rmkx]}
1351 }
1352 function zle-line-init () {
1353 zle-smkx
1354 }
1355 function zle-line-finish () {
1356 zle-rmkx
1357 }
1358 zle -N zle-line-init
1359 zle -N zle-line-finish
1360else
1361 for i in {s,r}mkx; do
1362 (( ${+terminfo[$i]} )) || grml_missing_features+=($i)
1363 done
1364 unset i
1365fi
1366
1367typeset -A key
1368key=(
1369 Home "${terminfo[khome]}"
1370 End "${terminfo[kend]}"
1371 Insert "${terminfo[kich1]}"
1372 Delete "${terminfo[kdch1]}"
1373 Up "${terminfo[kcuu1]}"
1374 Down "${terminfo[kcud1]}"
1375 Left "${terminfo[kcub1]}"
1376 Right "${terminfo[kcuf1]}"
1377 PageUp "${terminfo[kpp]}"
1378 PageDown "${terminfo[knp]}"
1379 BackTab "${terminfo[kcbt]}"
1380)
1381
1382# Guidelines for adding key bindings:
1383#
1384# - Do not add hardcoded escape sequences, to enable non standard key
1385# combinations such as Ctrl-Meta-Left-Cursor. They are not easily portable.
1386#
1387# - Adding Ctrl characters, such as '^b' is okay; note that '^b' and '^B' are
1388# the same key.
1389#
1390# - All keys from the $key[] mapping are obviously okay.
1391#
1392# - Most terminals send "ESC x" when Meta-x is pressed. Thus, sequences like
1393# '\ex' are allowed in here as well.
1394
1395bind2maps emacs -- Home beginning-of-somewhere
1396bind2maps viins vicmd -- Home vi-beginning-of-line
1397bind2maps emacs -- End end-of-somewhere
1398bind2maps viins vicmd -- End vi-end-of-line
1399bind2maps emacs viins -- Insert overwrite-mode
1400bind2maps vicmd -- Insert vi-insert
1401bind2maps emacs -- Delete delete-char
1402bind2maps viins vicmd -- Delete vi-delete-char
1403bind2maps emacs viins vicmd -- Up up-line-or-search
1404bind2maps emacs viins vicmd -- Down down-line-or-search
1405bind2maps emacs -- Left backward-char
1406bind2maps viins vicmd -- Left vi-backward-char
1407bind2maps emacs -- Right forward-char
1408bind2maps viins vicmd -- Right vi-forward-char
1409bind2maps viins vicmd -- Right vi-forward-char
1410#k# Display list of abbreviations that expand when followed by ,.
1411bind2maps emacs viins -- -s ',.' zleiab
1412bind2maps emacs viins -- -s '^xb' help-show-abk
1413bind2maps emacs viins -- -s '^xM' inplaceMkDirs
1414#k# display help for keybindings and ZLE
1415bind2maps emacs viins -- -s '^xz' help-zle
1416#k# Insert files and test globbing
1417bind2maps emacs viins -- -s "^xf" insert-files
1418#k# Edit the current line in \kbd{\$EDITOR}
1419bind2maps emacs viins -- -s '\ee' edit-command-line
1420#k# search history backward for entry beginning with typed text
1421bind2maps emacs viins -- -s '^xp' history-beginning-search-backward-end
1422#k# search history forward for entry beginning with typed text
1423bind2maps emacs viins -- -s '^xP' history-beginning-search-forward-end
1424#k# search history backward for entry beginning with typed text
1425bind2maps emacs viins -- PageUp history-beginning-search-backward-end
1426#k# search history forward for entry beginning with typed text
1427bind2maps emacs viins -- PageDown history-beginning-search-forward-end
1428#k# Toggle abbreviation expansion on/off
1429bind2maps emacs viins -- -s '^xA' grml_toggle_abbrev
1430bind2maps emacs viins -- -s "^x^h" commit-to-history
1431#k# Kill left-side word or everything up to next slash
1432bind2maps emacs viins -- -s '\ev' slash-backward-kill-word
1433#k# Kill left-side word or everything up to next slash
1434bind2maps emacs viins -- -s '\e^h' slash-backward-kill-word
1435#k# Kill left-side word or everything up to next slash
1436bind2maps emacs viins -- -s '\e^?' slash-backward-kill-word
1437# Do history expansion on space:
1438bind2maps emacs viins -- -s ' ' magic-space
1439#k# Trigger menu-complete
1440bind2maps emacs viins -- -s '\ei' menu-complete # menu completion via esc-i
1441#k# Insert a timestamp on the command line (yyyy-mm-dd)
1442bind2maps emacs viins -- -s '^ed' insert-datestamp
1443#k# Insert last typed word
1444bind2maps emacs viins -- -s "\em" insert-last-typed-word
1445#k# A smart shortcut for \kbd{fg<enter>}
1446bind2maps emacs viins -- -s '^z' grml-zsh-fg
1447#k# prepend the current command with "sudo"
1448bind2maps emacs viins -- -s "^os" sudo-command-line
1449#k# jump to after first word (for adding options)
1450bind2maps emacs viins -- -s '^x1' jump_after_first_word
1451#k# complete word from history with menu
1452bind2maps emacs viins -- -s "^x^x" hist-complete
1453
1454# insert unicode character
1455# usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an §
1456# See for example http://unicode.org/charts/ for unicode characters code
1457#k# Insert Unicode character
1458bind2maps emacs viins -- -s '^xi' insert-unicode-char
1459
1460# use the new *-pattern-* widgets for incremental history search
1461if zrcgotwidget history-incremental-pattern-search-backward; then
1462 for seq wid in '^r' history-incremental-pattern-search-backward \
1463 '^s' history-incremental-pattern-search-forward
1464 do
1465 bind2maps emacs viins vicmd -- -s $seq $wid
1466 done
1467fi
1468
1469if zrcgotkeymap menuselect; then
1470 #m# k Shift-tab Perform backwards menu completion
1471 bind2maps menuselect -- BackTab reverse-menu-complete
1472
1473 #k# menu selection: pick item but stay in the menu
1474 bind2maps menuselect -- -s '\e^M' accept-and-menu-complete
1475 # also use + and INSERT since it's easier to press repeatedly
1476 bind2maps menuselect -- -s '+' accept-and-menu-complete
1477 bind2maps menuselect -- Insert accept-and-menu-complete
1478
1479 # accept a completion and try to complete again by using menu
1480 # completion; very useful with completing directories
1481 # by using 'undo' one's got a simple file browser
1482 bind2maps menuselect -- -s '^o' accept-and-infer-next-history
1483fi
1484
1485# Finally, here are still a few hardcoded escape sequences; Special sequences
1486# like Ctrl-<Cursor-key> etc do suck a fair bit, because they are not
1487# standardised and most of the time are not available in a terminals terminfo
1488# entry.
1489#
1490# While we do not encourage adding bindings like these, we will keep these for
1491# backward compatibility.
1492
1493## use Ctrl-left-arrow and Ctrl-right-arrow for jumping to word-beginnings on
1494## the command line.
1495# URxvt sequences:
1496bind2maps emacs viins vicmd -- -s '\eOc' forward-word
1497bind2maps emacs viins vicmd -- -s '\eOd' backward-word
1498# These are for xterm:
1499bind2maps emacs viins vicmd -- -s '\e[1;5C' forward-word
1500bind2maps emacs viins vicmd -- -s '\e[1;5D' backward-word
1501## the same for alt-left-arrow and alt-right-arrow
1502# URxvt again:
1503bind2maps emacs viins vicmd -- -s '\e\e[C' forward-word
1504bind2maps emacs viins vicmd -- -s '\e\e[D' backward-word
1505# Xterm again:
1506bind2maps emacs viins vicmd -- -s '^[[1;3C' forward-word
1507bind2maps emacs viins vicmd -- -s '^[[1;3D' backward-word
1508# Also try ESC Left/Right:
1509bind2maps emacs viins vicmd -- -s '\e'${key[Right]} forward-word
1510bind2maps emacs viins vicmd -- -s '\e'${key[Left]} backward-word
1511
1512# autoloading
1513
1514zrcautoload zmv
1515zrcautoload zed
1516
1517# we don't want to quote/espace URLs on our own...
1518# if autoload -U url-quote-magic ; then
1519# zle -N self-insert url-quote-magic
1520# zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
1521# else
1522# print 'Notice: no url-quote-magic available :('
1523# fi
1524alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
1525
1526#m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
1527alias run-help >&/dev/null && unalias run-help
1528for rh in run-help{,-git,-svk,-svn}; do
1529 zrcautoload $rh
1530done; unset rh
1531
1532# command not found handling
1533
1534(( ${COMMAND_NOT_FOUND} == 1 )) &&
1535function command_not_found_handler() {
1536 emulate -L zsh
1537 if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1538 ${GRML_ZSH_CNF_HANDLER} $1
1539 fi
1540 return 1
1541}
1542
1543# history
1544
1545ZSHDIR=${ZDOTDIR:-${HOME}/.zsh}
1546
1547#v#
1548HISTFILE=${ZDOTDIR:-${HOME}}/.zsh_history
1549isgrmlcd && HISTSIZE=500 || HISTSIZE=5000
1550isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1551
1552# dirstack handling
1553
1554DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1555DIRSTACKFILE=${DIRSTACKFILE:-${ZDOTDIR:-${HOME}}/.zdirs}
1556
1557if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1558 dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1559 # "cd -" won't work after login by just setting $OLDPWD, so
1560 [[ -d $dirstack[1] ]] && cd $dirstack[1] && cd $OLDPWD
1561fi
1562
1563chpwd() {
1564 local -ax my_stack
1565 my_stack=( ${PWD} ${dirstack} )
1566 if is42 ; then
1567 builtin print -l ${(u)my_stack} >! ${DIRSTACKFILE}
1568 else
1569 uprint my_stack >! ${DIRSTACKFILE}
1570 fi
1571}
1572
1573# directory based profiles
1574
1575if is433 ; then
1576
1577# chpwd_profiles(): Directory Profiles, Quickstart:
1578#
1579# In .zshrc.local:
1580#
1581# zstyle ':chpwd:profiles:/usr/src/grml(|/|/*)' profile grml
1582# zstyle ':chpwd:profiles:/usr/src/debian(|/|/*)' profile debian
1583# chpwd_profiles
1584#
1585# For details see the `grmlzshrc.5' manual page.
1586function chpwd_profiles() {
1587 local profile context
1588 local -i reexecute
1589
1590 context=":chpwd:profiles:$PWD"
1591 zstyle -s "$context" profile profile || profile='default'
1592 zstyle -T "$context" re-execute && reexecute=1 || reexecute=0
1593
1594 if (( ${+parameters[CHPWD_PROFILE]} == 0 )); then
1595 typeset -g CHPWD_PROFILE
1596 local CHPWD_PROFILES_INIT=1
1597 (( ${+functions[chpwd_profiles_init]} )) && chpwd_profiles_init
1598 elif [[ $profile != $CHPWD_PROFILE ]]; then
1599 (( ${+functions[chpwd_leave_profile_$CHPWD_PROFILE]} )) \
1600 && chpwd_leave_profile_${CHPWD_PROFILE}
1601 fi
1602 if (( reexecute )) || [[ $profile != $CHPWD_PROFILE ]]; then
1603 (( ${+functions[chpwd_profile_$profile]} )) && chpwd_profile_${profile}
1604 fi
1605
1606 CHPWD_PROFILE="${profile}"
1607 return 0
1608}
1609
1610chpwd_functions=( ${chpwd_functions} chpwd_profiles )
1611
1612fi # is433
1613
1614# Prompt setup for grml:
1615
1616# set colors for use in prompts (modern zshs allow for the use of %F{red}foo%f
1617# in prompts to get a red "foo" embedded, but it's good to keep these for
1618# backwards compatibility).
1619if zrcautoload colors && colors 2>/dev/null ; then
1620 BLUE="%{${fg[blue]}%}"
1621 RED="%{${fg_bold[red]}%}"
1622 GREEN="%{${fg[green]}%}"
1623 CYAN="%{${fg[cyan]}%}"
1624 MAGENTA="%{${fg[magenta]}%}"
1625 YELLOW="%{${fg[yellow]}%}"
1626 WHITE="%{${fg[white]}%}"
1627 NO_COLOR="%{${reset_color}%}"
1628else
1629 BLUE=$'%{\e[1;34m%}'
1630 RED=$'%{\e[1;31m%}'
1631 GREEN=$'%{\e[1;32m%}'
1632 CYAN=$'%{\e[1;36m%}'
1633 WHITE=$'%{\e[1;37m%}'
1634 MAGENTA=$'%{\e[1;35m%}'
1635 YELLOW=$'%{\e[1;33m%}'
1636 NO_COLOR=$'%{\e[0m%}'
1637fi
1638
1639# First, the easy ones: PS2..4:
1640
1641# secondary prompt, printed when the shell needs more information to complete a
1642# command.
1643PS2='\`%_> '
1644# selection prompt used within a select loop.
1645PS3='?# '
1646# the execution trace prompt (setopt xtrace). default: '+%N:%i>'
1647PS4='+%N:%i:%_> '
1648
1649# Some additional features to use with our prompt:
1650#
1651# - battery status
1652# - debian_chroot
1653# - vcs_info setup and version specific fixes
1654
1655# display battery status on right side of prompt via running 'BATTERY=1 zsh'
1656if [[ $BATTERY -gt 0 ]] ; then
1657 if ! check_com -c acpi ; then
1658 BATTERY=0
1659 fi
1660fi
1661
1662battery() {
1663if [[ $BATTERY -gt 0 ]] ; then
1664 PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1665 if [[ -z "$PERCENT" ]] ; then
1666 PERCENT='acpi not present'
1667 else
1668 if [[ "$PERCENT" -lt 20 ]] ; then
1669 PERCENT="warning: ${PERCENT}%%"
1670 else
1671 PERCENT="${PERCENT}%%"
1672 fi
1673 fi
1674fi
1675}
1676
1677# set variable debian_chroot if running in a chroot with /etc/debian_chroot
1678if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
1679 debian_chroot=$(</etc/debian_chroot)
1680fi
1681
1682# gather version control information for inclusion in a prompt
1683
1684if zrcautoload vcs_info; then
1685 # `vcs_info' in zsh versions 4.3.10 and below have a broken `_realpath'
1686 # function, which can cause a lot of trouble with our directory-based
1687 # profiles. So:
1688 if [[ ${ZSH_VERSION} == 4.3.<-10> ]] ; then
1689 function VCS_INFO_realpath () {
1690 setopt localoptions NO_shwordsplit chaselinks
1691 ( builtin cd -q $1 2> /dev/null && pwd; )
1692 }
1693 fi
1694
1695 zstyle ':vcs_info:*' max-exports 2
1696
1697 if [[ -o restricted ]]; then
1698 zstyle ':vcs_info:*' enable NONE
1699 fi
1700fi
1701
1702# Change vcs_info formats for the grml prompt. The 2nd format sets up
1703# $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1704# TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1705# That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1706# to $vcs_info_msg_N_ as soon as we use the included version.
1707if [[ "$TERM" == dumb ]] ; then
1708 zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1709 zstyle ':vcs_info:*' formats "(%s%)-[%b] " "zsh: %r"
1710else
1711 # these are the same, just with a lot of colors:
1712 zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOR} " \
1713 "zsh: %r"
1714 zstyle ':vcs_info:*' formats "${MAGENTA}(${NO_COLOR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOR}%} " \
1715 "zsh: %r"
1716 zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1717fi
1718
1719# Now for the fun part: The grml prompt themes in `promptsys' mode of operation
1720
1721# This actually defines three prompts:
1722#
1723# - grml
1724# - grml-large
1725# - grml-chroot
1726#
1727# They all share the same code and only differ with respect to which items they
1728# contain. The main source of documentation is the `prompt_grml_help' function
1729# below, which gets called when the user does this: prompt -h grml
1730
1731function prompt_grml_help () {
1732 cat <<__EOF0__
1733 prompt grml
1734 This is the prompt as used by the grml-live system <http://grml.org>. It is
1735 a rather simple one-line prompt, that by default looks something like this:
1736 <user>@<host> <current-working-directory>[ <vcs_info-data>]%
1737 The prompt itself integrates with zsh's prompt themes system (as you are
1738 witnessing right now) and is configurable to a certain degree. In
1739 particular, these aspects are customisable:
1740 - The items used in the prompt (e.g. you can remove \`user' from
1741 the list of activated items, which will cause the user name to
1742 be omitted from the prompt string).
1743 - The attributes used with the items are customisable via strings
1744 used before and after the actual item.
1745 The available items are: at, battery, change-root, date, grml-chroot,
1746 history, host, jobs, newline, path, percent, rc, rc-always, sad-smiley,
1747 shell-level, time, user, vcs
1748 The actual configuration is done via zsh's \`zstyle' mechanism. The
1749 context, that is used while looking up styles is:
1750 ':prompt:grml:<left-or-right>:<subcontext>'
1751 Here <left-or-right> is either \`left' or \`right', signifying whether the
1752 style should affect the left or the right prompt. <subcontext> is either
1753 \`setup' or 'items:<item>', where \`<item>' is one of the available items.
1754 The styles:
1755 - use-rprompt (boolean): If \`true' (the default), print a sad smiley
1756 in $RPROMPT if the last command a returned non-successful error code.
1757 (This in only valid if <left-or-right> is "right"; ignored otherwise)
1758 - items (list): The list of items used in the prompt. If \`vcs' is
1759 present in the list, the theme's code invokes \`vcs_info'
1760 accordingly. Default (left): rc change-root user at host path vcs
1761 percent; Default (right): sad-smiley
1762 Available styles in 'items:<item>' are: pre, post. These are strings that
1763 are inserted before (pre) and after (post) the item in question. Thus, the
1764 following would cause the user name to be printed in red instead of the
1765 default blue:
1766 zstyle ':prompt:grml:*:items:user' pre '%F{red}'
1767 Note, that the \`post' style may remain at its default value, because its
1768 default value is '%f', which turns the foreground text attribute off (which
1769 is exactly, what is still required with the new \`pre' value).
1770__EOF0__
1771}
1772
1773function prompt_grml-chroot_help () {
1774 cat <<__EOF0__
1775 prompt grml-chroot
1776 This is a variation of the grml prompt, see: prompt -h grml
1777 The main difference is the default value of the \`items' style. The rest
1778 behaves exactly the same. Here are the defaults for \`grml-chroot':
1779 - left: grml-chroot user at host path percent
1780 - right: (empty list)
1781__EOF0__
1782}
1783
1784function prompt_grml-large_help () {
1785 cat <<__EOF0__
1786 prompt grml-large
1787 This is a variation of the grml prompt, see: prompt -h grml
1788 The main difference is the default value of the \`items' style. In
1789 particular, this theme uses _two_ lines instead of one with the plain
1790 \`grml' theme. The rest behaves exactly the same. Here are the defaults
1791 for \`grml-large':
1792 - left: rc jobs history shell-level change-root time date newline user
1793 at host path vcs percent
1794 - right: sad-smiley
1795__EOF0__
1796}
1797
1798function grml_prompt_setup () {
1799 emulate -L zsh
1800 autoload -Uz vcs_info
1801 autoload -Uz add-zsh-hook
1802 add-zsh-hook precmd prompt_$1_precmd
1803}
1804
1805function prompt_grml_setup () {
1806 grml_prompt_setup grml
1807}
1808
1809function prompt_grml-chroot_setup () {
1810 grml_prompt_setup grml-chroot
1811}
1812
1813function prompt_grml-large_setup () {
1814 grml_prompt_setup grml-large
1815}
1816
1817# These maps define default tokens and pre-/post-decoration for items to be
1818# used within the themes. All defaults may be customised in a context sensitive
1819# matter by using zsh's `zstyle' mechanism.
1820typeset -gA grml_prompt_pre_default \
1821 grml_prompt_post_default \
1822 grml_prompt_token_default \
1823 grml_prompt_token_function
1824
1825grml_prompt_pre_default=(
1826 at ''
1827 battery ' '
1828 change-root ''
1829 date '%F{blue}'
1830 grml-chroot '%F{red}'
1831 history '%F{green}'
1832 host ''
1833 jobs '%F{cyan}'
1834 newline ''
1835 path '%B'
1836 percent ''
1837 rc '%B%F{red}'
1838 rc-always ''
1839 sad-smiley ''
1840 shell-level '%F{red}'
1841 time '%F{blue}'
1842 user '%B%F{blue}'
1843 vcs ''
1844)
1845
1846grml_prompt_post_default=(
1847 at ''
1848 battery ''
1849 change-root ''
1850 date '%f'
1851 grml-chroot '%f '
1852 history '%f'
1853 host ''
1854 jobs '%f'
1855 newline ''
1856 path '%b'
1857 percent ''
1858 rc '%f%b'
1859 rc-always ''
1860 sad-smiley ''
1861 shell-level '%f'
1862 time '%f'
1863 user '%f%b'
1864 vcs ''
1865)
1866
1867grml_prompt_token_default=(
1868 at '@'
1869 battery 'PERCENT'
1870 change-root 'debian_chroot'
1871 date '%D{%Y-%m-%d}'
1872 grml-chroot 'GRML_CHROOT'
1873 history '{history#%!} '
1874 host '%m '
1875 jobs '[%j running job(s)] '
1876 newline $'\n'
1877 path '%40<..<%~%<< '
1878 percent '%# '
1879 rc '%(?..%? )'
1880 rc-always '%?'
1881 sad-smiley '%(?..:()'
1882 shell-level '%(3L.+ .)'
1883 time '%D{%H:%M:%S} '
1884 user '%n'
1885 vcs '0'
1886)
1887
1888function GRML_theme_add_token_usage () {
1889 cat <<__EOF__
1890 Usage: grml_theme_add_token <name> [-f|-i] <token/function> [<pre> <post>]
1891 <name> is the name for the newly added token. If the \`-f' or \`-i' options
1892 are used, <token/function> is the name of the function (see below for
1893 details). Otherwise it is the literal token string to be used. <pre> and
1894 <post> are optional.
1895 Options:
1896 -f <function> Use a function named \`<function>' each time the token
1897 is to be expanded.
1898 -i <function> Use a function named \`<function>' to initialise the
1899 value of the token _once_ at runtime.
1900 The functions are called with one argument: the token's new name. The
1901 return value is expected in the \$REPLY parameter. The use of these
1902 options is mutually exclusive.
1903 Example:
1904 To add a new token \`day' that expands to the current weekday in the
1905 current locale in green foreground colour, use this:
1906 grml_theme_add_token day '%D{%A}' '%F{green}' '%f'
1907 Another example would be support for \$VIRTUAL_ENV:
1908 function virtual_env_prompt () {
1909 REPLY=\${VIRTUAL_ENV+\${VIRTUAL_ENV:t} }
1910 }
1911 grml_theme_add_token virtual-env -f virtual_env_prompt
1912 After that, you will be able to use a changed \`items' style to
1913 assemble your prompt.
1914__EOF__
1915}
1916
1917function grml_theme_add_token () {
1918 emulate -L zsh
1919 local name token pre post
1920 local -i init funcall
1921
1922 if (( ARGC == 0 )); then
1923 GRML_theme_add_token_usage
1924 return 0
1925 fi
1926
1927 init=0
1928 funcall=0
1929 pre=''
1930 post=''
1931 name=$1
1932 shift
1933 if [[ $1 == '-f' ]]; then
1934 funcall=1
1935 shift
1936 elif [[ $1 == '-i' ]]; then
1937 init=1
1938 shift
1939 fi
1940
1941 if (( ARGC == 0 )); then
1942 printf '
1943grml_theme_add_token: No token-string/function-name provided!\n\n'
1944 GRML_theme_add_token_usage
1945 return 1
1946 fi
1947 token=$1
1948 shift
1949 if (( ARGC != 0 && ARGC != 2 )); then
1950 printf '
1951grml_theme_add_token: <pre> and <post> need to by specified _both_!\n\n'
1952 GRML_theme_add_token_usage
1953 return 1
1954 fi
1955 if (( ARGC )); then
1956 pre=$1
1957 post=$2
1958 shift 2
1959 fi
1960
1961 if (( ${+grml_prompt_token_default[$name]} )); then
1962 printf '
1963grml_theme_add_token: Token `%s'\'' exists! Giving up!\n\n' $name
1964 GRML_theme_add_token_usage
1965 return 2
1966 fi
1967 if (( init )); then
1968 $token $name
1969 token=$REPLY
1970 fi
1971 grml_prompt_pre_default[$name]=$pre
1972 grml_prompt_post_default[$name]=$post
1973 if (( funcall )); then
1974 grml_prompt_token_function[$name]=$token
1975 grml_prompt_token_default[$name]=23
1976 else
1977 grml_prompt_token_default[$name]=$token
1978 fi
1979}
1980
1981function grml_typeset_and_wrap () {
1982 emulate -L zsh
1983 local target="$1"
1984 local new="$2"
1985 local left="$3"
1986 local right="$4"
1987
1988 if (( ${+parameters[$new]} )); then
1989 typeset -g "${target}=${(P)target}${left}${(P)new}${right}"
1990 fi
1991}
1992
1993function grml_prompt_addto () {
1994 emulate -L zsh
1995 local target="$1"
1996 local lr it apre apost new v
1997 local -a items
1998 shift
1999
2000 [[ $target == PS1 ]] && lr=left || lr=right
2001 zstyle -a ":prompt:${grmltheme}:${lr}:setup" items items || items=( "$@" )
2002 typeset -g "${target}="
2003 for it in "${items[@]}"; do
2004 zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" pre apre \
2005 || apre=${grml_prompt_pre_default[$it]}
2006 zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" post apost \
2007 || apost=${grml_prompt_post_default[$it]}
2008 zstyle -s ":prompt:${grmltheme}:${lr}:items:$it" token new \
2009 || new=${grml_prompt_token_default[$it]}
2010 typeset -g "${target}=${(P)target}${apre}"
2011 if (( ${+grml_prompt_token_function[$it]} )); then
2012 ${grml_prompt_token_function[$it]} $it
2013 typeset -g "${target}=${(P)target}${REPLY}"
2014 else
2015 case $it in
2016 battery)
2017 grml_typeset_and_wrap $target $new '' ''
2018 ;;
2019 change-root)
2020 grml_typeset_and_wrap $target $new '(' ')'
2021 ;;
2022 grml-chroot)
2023 if [[ -n ${(P)new} ]]; then
2024 typeset -g "${target}=${(P)target}(CHROOT)"
2025 fi
2026 ;;
2027 vcs)
2028 v="vcs_info_msg_${new}_"
2029 if (( ! vcscalled )); then
2030 vcs_info
2031 vcscalled=1
2032 fi
2033 if (( ${+parameters[$v]} )) && [[ -n "${(P)v}" ]]; then
2034 typeset -g "${target}=${(P)target}${(P)v}"
2035 fi
2036 ;;
2037 *) typeset -g "${target}=${(P)target}${new}" ;;
2038 esac
2039 fi
2040 typeset -g "${target}=${(P)target}${apost}"
2041 done
2042}
2043
2044function prompt_grml_precmd () {
2045 emulate -L zsh
2046 local grmltheme=grml
2047 local -a left_items right_items
2048 left_items=(rc change-root user at host path vcs percent)
2049 right_items=(sad-smiley)
2050
2051 prompt_grml_precmd_worker
2052}
2053
2054function prompt_grml-chroot_precmd () {
2055 emulate -L zsh
2056 local grmltheme=grml-chroot
2057 local -a left_items right_items
2058 left_items=(grml-chroot user at host path percent)
2059 right_items=()
2060
2061 prompt_grml_precmd_worker
2062}
2063
2064function prompt_grml-large_precmd () {
2065 emulate -L zsh
2066 local grmltheme=grml-large
2067 local -a left_items right_items
2068 left_items=(rc jobs history shell-level change-root time date newline
2069 user at host path vcs percent)
2070 right_items=(sad-smiley)
2071
2072 prompt_grml_precmd_worker
2073}
2074
2075function prompt_grml_precmd_worker () {
2076 emulate -L zsh
2077 local -i vcscalled=0
2078
2079 grml_prompt_addto PS1 "${left_items[@]}"
2080 if zstyle -T ":prompt:${grmltheme}:right:setup" use-rprompt; then
2081 grml_prompt_addto RPS1 "${right_items[@]}"
2082 fi
2083}
2084
2085grml_prompt_fallback() {
2086 setopt prompt_subst
2087 precmd() {
2088 (( ${+functions[vcs_info]} )) && vcs_info
2089 }
2090
2091 p0="${RED}%(?..%? )${WHITE}${debian_chroot:+($debian_chroot)}"
2092 p1="${BLUE}%n${NO_COLOR}@%m %40<...<%B%~%b%<< "'${vcs_info_msg_0_}'"%# "
2093 if (( EUID == 0 )); then
2094 PROMPT="${BLUE}${p0}${RED}${p1}"
2095 else
2096 PROMPT="${RED}${p0}${BLUE}${p1}"
2097 fi
2098 unset p0 p1
2099}
2100
2101if zrcautoload promptinit && promptinit 2>/dev/null ; then
2102 # Since we define the required functions in here and not in files in
2103 # $fpath, we need to stick the theme's name into `$prompt_themes'
2104 # ourselves, since promptinit does not pick them up otherwise.
2105 prompt_themes+=( grml grml-chroot grml-large )
2106 # Also, keep the array sorted...
2107 prompt_themes=( "${(@on)prompt_themes}" )
2108else
2109 print 'Notice: no promptinit available :('
2110 grml_prompt_fallback
2111fi
2112
2113if is437; then
2114 # The prompt themes use modern features of zsh, that require at least
2115 # version 4.3.7 of the shell. Use the fallback otherwise.
2116 if [[ $BATTERY -gt 0 ]]; then
2117 zstyle ':prompt:grml:right:setup' items sad-smiley battery
2118 add-zsh-hook precmd battery
2119 fi
2120 if [[ "$TERM" == dumb ]] ; then
2121 zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" pre ''
2122 zstyle ":prompt:grml(|-large|-chroot):*:items:grml-chroot" post ' '
2123 for i in rc user path jobs history date time shell-level; do
2124 zstyle ":prompt:grml(|-large|-chroot):*:items:$i" pre ''
2125 zstyle ":prompt:grml(|-large|-chroot):*:items:$i" post ''
2126 done
2127 unset i
2128 zstyle ':prompt:grml(|-large|-chroot):right:setup' use-rprompt false
2129 elif (( EUID == 0 )); then
2130 zstyle ':prompt:grml(|-large|-chroot):*:items:user' pre '%B%F{red}'
2131 fi
2132
2133 # Finally enable one of the prompts.
2134 if [[ -n $GRML_CHROOT ]]; then
2135 prompt grml-chroot
2136 elif [[ $GRMLPROMPT -gt 0 ]]; then
2137 prompt grml-large
2138 else
2139 prompt grml
2140 fi
2141else
2142 grml_prompt_fallback
2143fi
2144
2145# Terminal-title wizardry
2146
2147function ESC_print () {
2148 info_print $'\ek' $'\e\\' "$@"
2149}
2150function set_title () {
2151 info_print $'\e]0;' $'\a' "$@"
2152}
2153
2154function info_print () {
2155 local esc_begin esc_end
2156 esc_begin="$1"
2157 esc_end="$2"
2158 shift 2
2159 printf '%s' ${esc_begin}
2160 printf '%s' "$*"
2161 printf '%s' "${esc_end}"
2162}
2163
2164function grml_reset_screen_title () {
2165 # adjust title of xterm
2166 # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
2167 [[ ${NOTITLE:-} -gt 0 ]] && return 0
2168 case $TERM in
2169 (xterm*|rxvt*)
2170 set_title ${(%):-"%n@%m: %~"}
2171 ;;
2172 esac
2173}
2174
2175function grml_vcs_to_screen_title () {
2176 if [[ $TERM == screen* ]] ; then
2177 if [[ -n ${vcs_info_msg_1_} ]] ; then
2178 ESC_print ${vcs_info_msg_1_}
2179 else
2180 ESC_print "zsh"
2181 fi
2182 fi
2183}
2184
2185function grml_maintain_name () {
2186 # set hostname if not running on host with name 'grml'
2187 if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
2188 NAME="@$HOSTNAME"
2189 fi
2190}
2191
2192function grml_cmd_to_screen_title () {
2193 # get the name of the program currently running and hostname of local
2194 # machine set screen window title if running in a screen
2195 if [[ "$TERM" == screen* ]] ; then
2196 local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME"
2197 ESC_print ${CMD}
2198 fi
2199}
2200
2201function grml_control_xterm_title () {
2202 case $TERM in
2203 (xterm*|rxvt*)
2204 set_title "${(%):-"%n@%m:"}" "$1"
2205 ;;
2206 esac
2207}
2208
2209zrcautoload add-zsh-hook || add-zsh-hook () { :; }
2210if [[ $NOPRECMD -eq 0 ]]; then
2211 add-zsh-hook precmd grml_reset_screen_title
2212 add-zsh-hook precmd grml_vcs_to_screen_title
2213 add-zsh-hook preexec grml_maintain_name
2214 add-zsh-hook preexec grml_cmd_to_screen_title
2215 if [[ $NOTITLE -eq 0 ]]; then
2216 add-zsh-hook preexec grml_control_xterm_title
2217 fi
2218fi
2219
2220# 'hash' some often used directories
2221#d# start
2222hash -d deb=/var/cache/apt/archives
2223hash -d doc=/usr/share/doc
2224hash -d linux=/lib/modules/$(command uname -r)/build/
2225hash -d log=/var/log
2226hash -d slog=/var/log/syslog
2227hash -d src=/usr/src
2228hash -d templ=/usr/share/doc/grml-templates
2229hash -d tt=/usr/share/doc/texttools-doc
2230hash -d www=/var/www
2231#d# end
2232
2233# some aliases
2234if check_com -c screen ; then
2235 if [[ $UID -eq 0 ]] ; then
2236 if [[ -r /etc/grml/screenrc ]]; then
2237 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2238 fi
2239 elif [[ -r $HOME/.screenrc ]] ; then
2240 alias screen="${commands[screen]} -c $HOME/.screenrc"
2241 else
2242 if [[ -r /etc/grml/screenrc_grml ]]; then
2243 alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2244 else
2245 if [[ -r /etc/grml/screenrc ]]; then
2246 alias screen="${commands[screen]} -c /etc/grml/screenrc"
2247 fi
2248 fi
2249 fi
2250fi
2251
2252# do we have GNU ls with color-support?
2253if [[ "$TERM" != dumb ]]; then
2254 #a1# List files with colors (\kbd{ls -b -CF \ldots})
2255 alias ls='ls -b -CF '${ls_options:+"${ls_options[*]}"}
2256 #a1# List all files, with colors (\kbd{ls -la \ldots})
2257 alias la='ls -la '${ls_options:+"${ls_options[*]}"}
2258 #a1# List files with long colored list, without dotfiles (\kbd{ls -l \ldots})
2259 alias ll='ls -l '${ls_options:+"${ls_options[*]}"}
2260 #a1# List files with long colored list, human readable sizes (\kbd{ls -hAl \ldots})
2261 alias lh='ls -hAl '${ls_options:+"${ls_options[*]}"}
2262 #a1# List files with long colored list, append qualifier to filenames (\kbd{ls -lF \ldots})\\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2263 alias l='ls -lF '${ls_options:+"${ls_options[*]}"}
2264else
2265 alias ls='ls -b -CF'
2266 alias la='ls -la'
2267 alias ll='ls -l'
2268 alias lh='ls -hAl'
2269 alias l='ls -lF'
2270fi
2271
2272alias mdstat='cat /proc/mdstat'
2273alias ...='cd ../../'
2274
2275# generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2276if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2277 alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2278fi
2279
2280# see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2281alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2282alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2283
2284# make sure it is not assigned yet
2285[[ -n ${aliases[utf2iso]} ]] && unalias utf2iso
2286utf2iso() {
2287 if isutfenv ; then
2288 for ENV in $(env | command grep -i '.utf') ; do
2289 eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2290 done
2291 fi
2292}
2293
2294# make sure it is not assigned yet
2295[[ -n ${aliases[iso2utf]} ]] && unalias iso2utf
2296iso2utf() {
2297 if ! isutfenv ; then
2298 for ENV in $(env | command grep -i '\.iso') ; do
2299 eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2300 done
2301 fi
2302}
2303
2304# especially for roadwarriors using GNU screen and ssh:
2305if ! check_com asc &>/dev/null ; then
2306 asc() { autossh -t "$@" 'screen -RdU' }
2307 compdef asc=ssh
2308fi
2309
2310#f1# Hints for the use of zsh on grml
2311zsh-help() {
2312 print "$bg[white]$fg[black]
2313zsh-help - hints for use of zsh on grml
2314=======================================$reset_color"
2315
2316 print '
2317Main configuration of zsh happens in /etc/zsh/zshrc.
2318That file is part of the package grml-etc-core, if you want to
2319use them on a non-grml-system just get the tar.gz from
2320http://deb.grml.org/ or (preferably) get it from the git repository:
2321 http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2322This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2323The file is still there, but it is empty for backwards compatibility.
2324For your own changes use these two files:
2325 $HOME/.zshrc.pre
2326 $HOME/.zshrc.local
2327The former is sourced very early in our zshrc, the latter is sourced
2328very lately.
2329System wide configuration without touching configuration files of grml
2330can take place in /etc/zsh/zshrc.local.
2331For information regarding zsh start at http://grml.org/zsh/
2332Take a look at grml'\''s zsh refcard:
2333% xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2334Check out the main zsh refcard:
2335% '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2336And of course visit the zsh-lovers:
2337% man zsh-lovers
2338You can adjust some options through environment variables when
2339invoking zsh without having to edit configuration files.
2340Basically meant for bash users who are not used to the power of
2341the zsh yet. :)
2342 "NOCOR=1 zsh" => deactivate automatic correction
2343 "NOMENU=1 zsh" => do not use auto menu completion
2344 (note: use ctrl-d for completion instead!)
2345 "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2346 "NOTITLE=1 zsh" => disable setting the title of xterms without disabling
2347 preexec() and precmd() completely
2348 "BATTERY=1 zsh" => activate battery status (via acpi) on right side of prompt
2349 "COMMAND_NOT_FOUND=1 zsh"
2350 => Enable a handler if an external command was not found
2351 The command called in the handler can be altered by setting
2352 the GRML_ZSH_CNF_HANDLER variable, the default is:
2353 "/usr/share/command-not-found/command-not-found"
2354A value greater than 0 is enables a feature; a value equal to zero
2355disables it. If you like one or the other of these settings, you can
2356add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2357zshrc.'
2358
2359 print "
2360$bg[white]$fg[black]
2361Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2362Enjoy your grml system with the zsh!$reset_color"
2363}
2364
2365# debian stuff
2366if [[ -r /etc/debian_version ]] ; then
2367 #a3# Execute \kbd{apt-cache search}
2368 alias acs='apt-cache search'
2369 #a3# Execute \kbd{apt-cache show}
2370 alias acsh='apt-cache show'
2371 #a3# Execute \kbd{apt-cache policy}
2372 alias acp='apt-cache policy'
2373 #a3# Execute \kbd{apt-get dist-upgrade}
2374 salias adg="apt-get dist-upgrade"
2375 #a3# Execute \kbd{apt-get install}
2376 salias agi="apt-get install"
2377 #a3# Execute \kbd{aptitude install}
2378 salias ati="aptitude install"
2379 #a3# Execute \kbd{apt-get upgrade}
2380 salias ag="apt-get upgrade"
2381 #a3# Execute \kbd{apt-get update}
2382 salias au="apt-get update"
2383 #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2384 salias -a up="aptitude update ; aptitude safe-upgrade"
2385 #a3# Execute \kbd{dpkg-buildpackage}
2386 alias dbp='dpkg-buildpackage'
2387 #a3# Execute \kbd{grep-excuses}
2388 alias ge='grep-excuses'
2389
2390 # get a root shell as normal user in live-cd mode:
2391 if isgrmlcd && [[ $UID -ne 0 ]] ; then
2392 alias su="sudo su"
2393 fi
2394
2395 #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2396 salias llog="$PAGER /var/log/syslog" # take a look at the syslog
2397 #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2398 salias tlog="tail -f /var/log/syslog" # follow the syslog
2399fi
2400
2401# sort installed Debian-packages by size
2402if check_com -c dpkg-query ; then
2403 #a3# List installed Debian-packages sorted by size
2404 alias debs-by-size="dpkg-query -Wf 'x \${Installed-Size} \${Package} \${Status}\n' | sed -ne '/^x /d' -e '/^x \(.*\) install ok installed$/s//\1/p' | sort -nr"
2405fi
2406
2407# if cdrecord is a symlink (to wodim) or isn't present at all warn:
2408if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord; then
2409 if check_com -c wodim; then
2410 cdrecord() {
2411 cat <<EOMESS
2412cdrecord is not provided under its original name by Debian anymore.
2413See #377109 in the BTS of Debian for more details.
2414Please use the wodim binary instead
2415EOMESS
2416 return 1
2417 }
2418 fi
2419fi
2420
2421# Use hard limits, except for a smaller stack and no core dumps
2422unlimit
2423is425 && limit stack 8192
2424isgrmlcd && limit core 0 # important for a live-cd-system
2425limit -s
2426
2427# grmlstuff
2428grmlstuff() {
2429# people should use 'grml-x'!
2430 if check_com -c 915resolution; then
2431 855resolution() {
2432 echo "Please use 915resolution as resolution modifying tool for Intel \
2433graphic chipset."
2434 return -1
2435 }
2436 fi
2437
2438 #a1# Output version of running grml
2439 alias grml-version='cat /etc/grml_version'
2440
2441 if check_com -c grml-debootstrap ; then
2442 debian2hd() {
2443 echo "Installing debian to harddisk is possible by using grml-debootstrap."
2444 return 1
2445 }
2446 fi
2447}
2448
2449# now run the functions
2450isgrml && checkhome
2451is4 && isgrml && grmlstuff
2452is4 && grmlcomp
2453
2454# keephack
2455is4 && xsource "/etc/zsh/keephack"
2456
2457# wonderful idea of using "e" glob qualifier by Peter Stephenson
2458# You use it as follows:
2459# $ NTREF=/reference/file
2460# $ ls -l *(e:nt:)
2461# This lists all the files in the current directory newer than the reference file.
2462# You can also specify the reference file inline; note quotes:
2463# $ ls -l *(e:'nt ~/.zshenv':)
2464is4 && nt() {
2465 if [[ -n $1 ]] ; then
2466 local NTREF=${~1}
2467 fi
2468 [[ $REPLY -nt $NTREF ]]
2469}
2470
2471# shell functions
2472
2473#f1# Reload an autoloadable function
2474freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2475compdef _functions freload
2476
2477#f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2478sll() {
2479 [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2480 for file in "$@" ; do
2481 while [[ -h "$file" ]] ; do
2482 ls -l $file
2483 file=$(readlink "$file")
2484 done
2485 done
2486}
2487
2488# TODO: Is it supported to use pager settings like this?
2489# PAGER='less -Mr' - If so, the use of $PAGER here needs fixing
2490# with respect to wordsplitting. (ie. ${=PAGER})
2491if check_com -c $PAGER ; then
2492 #f3# View Debian's changelog of a given package
2493 dchange() {
2494 emulate -L zsh
2495 if [[ -r /usr/share/doc/$1/changelog.Debian.gz ]] ; then
2496 $PAGER /usr/share/doc/$1/changelog.Debian.gz
2497 elif [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2498 $PAGER /usr/share/doc/$1/changelog.gz
2499 else
2500 if check_com -c aptitude ; then
2501 echo "No changelog for package $1 found, using aptitude to retrieve it."
2502 if isgrml ; then
2503 aptitude -t unstable changelog $1
2504 else
2505 aptitude changelog $1
2506 fi
2507 else
2508 echo "No changelog for package $1 found, sorry."
2509 return 1
2510 fi
2511 fi
2512 }
2513 _dchange() { _files -W /usr/share/doc -/ }
2514 compdef _dchange dchange
2515
2516 #f3# View Debian's NEWS of a given package
2517 dnews() {
2518 emulate -L zsh
2519 if [[ -r /usr/share/doc/$1/NEWS.Debian.gz ]] ; then
2520 $PAGER /usr/share/doc/$1/NEWS.Debian.gz
2521 else
2522 if [[ -r /usr/share/doc/$1/NEWS.gz ]] ; then
2523 $PAGER /usr/share/doc/$1/NEWS.gz
2524 else
2525 echo "No NEWS file for package $1 found, sorry."
2526 return 1
2527 fi
2528 fi
2529 }
2530 _dnews() { _files -W /usr/share/doc -/ }
2531 compdef _dnews dnews
2532
2533 #f3# View Debian's copyright of a given package
2534 dcopyright() {
2535 emulate -L zsh
2536 if [[ -r /usr/share/doc/$1/copyright ]] ; then
2537 $PAGER /usr/share/doc/$1/copyright
2538 else
2539 echo "No copyright file for package $1 found, sorry."
2540 return 1
2541 fi
2542 }
2543 _dcopyright() { _files -W /usr/share/doc -/ }
2544 compdef _dcopyright dcopyright
2545
2546 #f3# View upstream's changelog of a given package
2547 uchange() {
2548 emulate -L zsh
2549 if [[ -r /usr/share/doc/$1/changelog.gz ]] ; then
2550 $PAGER /usr/share/doc/$1/changelog.gz
2551 else
2552 echo "No changelog for package $1 found, sorry."
2553 return 1
2554 fi
2555 }
2556 _uchange() { _files -W /usr/share/doc -/ }
2557 compdef _uchange uchange
2558fi
2559
2560# zsh profiling
2561profile() {
2562 ZSH_PROFILE_RC=1 $SHELL "$@"
2563}
2564
2565#f1# Edit an alias via zle
2566edalias() {
2567 [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2568}
2569compdef _aliases edalias
2570
2571#f1# Edit a function via zle
2572edfunc() {
2573 [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
2574}
2575compdef _functions edfunc
2576
2577# use it e.g. via 'Restart apache2'
2578#m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2579#m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2580#m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2581#m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2582#m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2583#m# f6 Status() \kbd{/etc/init.d/\em{process}}\quad\kbd{status}
2584if [[ -d /etc/init.d || -d /etc/service ]] ; then
2585 __start_stop() {
2586 local action_="${1:l}" # e.g Start/Stop/Restart
2587 local service_="$2"
2588 local param_="$3"
2589
2590 local service_target_="$(readlink /etc/init.d/$service_)"
2591 if [[ $service_target_ == "/usr/bin/sv" ]]; then
2592 # runit
2593 case "${action_}" in
2594 start) if [[ ! -e /etc/service/$service_ ]]; then
2595 $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2596 else
2597 $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2598 fi ;;
2599 # there is no reload in runits sysv emulation
2600 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2601 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2602 esac
2603 else
2604 # sysvinit
2605 $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2606 fi
2607 }
2608
2609 _grmlinitd() {
2610 local -a scripts
2611 scripts=( /etc/init.d/*(x:t) )
2612 _describe "service startup script" scripts
2613 }
2614
2615 for i in Start Restart Stop Force-Reload Reload Status ; do
2616 eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2617 compdef _grmlinitd $i
2618 done
2619fi
2620
2621#f1# Provides useful information on globbing
2622H-Glob() {
2623 echo -e "
2624 / directories
2625 . plain files
2626 @ symbolic links
2627 = sockets
2628 p named pipes (FIFOs)
2629 * executable plain files (0100)
2630 % device files (character or block special)
2631 %b block special files
2632 %c character special files
2633 r owner-readable files (0400)
2634 w owner-writable files (0200)
2635 x owner-executable files (0100)
2636 A group-readable files (0040)
2637 I group-writable files (0020)
2638 E group-executable files (0010)
2639 R world-readable files (0004)
2640 W world-writable files (0002)
2641 X world-executable files (0001)
2642 s setuid files (04000)
2643 S setgid files (02000)
2644 t files with the sticky bit (01000)
2645 print *(m-1) # Files modified up to a day ago
2646 print *(a1) # Files accessed a day ago
2647 print *(@) # Just symlinks
2648 print *(Lk+50) # Files bigger than 50 kilobytes
2649 print *(Lk-50) # Files smaller than 50 kilobytes
2650 print **/*.c # All *.c files recursively starting in \$PWD
2651 print **/*.c~file.c # Same as above, but excluding 'file.c'
2652 print (foo|bar).* # Files starting with 'foo' or 'bar'
2653 print *~*.* # All Files that do not contain a dot
2654 chmod 644 *(.^x) # make all plain non-executable files publically readable
2655 print -l *(.c|.h) # Lists *.c and *.h
2656 print **/*(g:users:) # Recursively match all files that are owned by group 'users'
2657 echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2658}
2659alias help-zshglob=H-Glob
2660
2661# grep for running process, like: 'any vim'
2662any() {
2663 emulate -L zsh
2664 unsetopt KSH_ARRAYS
2665 if [[ -z "$1" ]] ; then
2666 echo "any - grep for process(es) by keyword" >&2
2667 echo "Usage: any <keyword>" >&2 ; return 1
2668 else
2669 ps xauwww | grep -i "${grep_options[@]}" "[${1[1]}]${1[2,-1]}"
2670 fi
2671}
2672
2673
2674# After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2675# taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2676[[ -r /proc/1/maps ]] && \
2677deswap() {
2678 print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2679 cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/') > /dev/null
2680 print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2681}
2682
2683# a wrapper for vim, that deals with title setting
2684# VIM_OPTIONS
2685# set this array to a set of options to vim you always want
2686# to have set when calling vim (in .zshrc.local), like:
2687# VIM_OPTIONS=( -p )
2688# This will cause vim to send every file given on the
2689# commandline to be send to it's own tab (needs vim7).
2690if check_com vim; then
2691 vim() {
2692 VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2693 }
2694fi
2695
2696# make a backup of a file
2697bk() {
2698 cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2699}
2700
2701ssl_hashes=( sha512 sha256 sha1 md5 )
2702
2703for sh in ${ssl_hashes}; do
2704 eval 'ssl-cert-'${sh}'() {
2705 emulate -L zsh
2706 if [[ -z $1 ]] ; then
2707 printf '\''usage: %s <file>\n'\'' "ssh-cert-'${sh}'"
2708 return 1
2709 fi
2710 openssl x509 -noout -fingerprint -'${sh}' -in $1
2711 }'
2712done; unset sh
2713
2714ssl-cert-fingerprints() {
2715 emulate -L zsh
2716 local i
2717 if [[ -z $1 ]] ; then
2718 printf 'usage: ssl-cert-fingerprints <file>\n'
2719 return 1
2720 fi
2721 for i in ${ssl_hashes}
2722 do ssl-cert-$i $1;
2723 done
2724}
2725
2726ssl-cert-info() {
2727 emulate -L zsh
2728 if [[ -z $1 ]] ; then
2729 printf 'usage: ssl-cert-info <file>\n'
2730 return 1
2731 fi
2732 openssl x509 -noout -text -in $1
2733 ssl-cert-fingerprints $1
2734}
2735
2736# make sure our environment is clean regarding colors
2737for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2738
2739# "persistent history"
2740# just write important commands you always need to ~/.important_commands
2741if [[ -r ~/.important_commands ]] ; then
2742 fc -R ~/.important_commands
2743fi
2744
2745# load the lookup subsystem if it's available on the system
2746zrcautoload lookupinit && lookupinit
2747
2748# variables
2749
2750# set terminal property (used e.g. by msgid-chooser)
2751export COLORTERM="yes"
2752
2753# aliases
2754
2755# general
2756#a2# Execute \kbd{du -sch}
2757alias da='du -sch'
2758#a2# Execute \kbd{jobs -l}
2759alias j='jobs -l'
2760
2761# listing stuff
2762#a2# Execute \kbd{ls -lSrah}
2763alias dir="ls -lSrah"
2764#a2# Only show dot-directories
2765alias lad='ls -d .*(/)'
2766#a2# Only show dot-files
2767alias lsa='ls -a .*(.)'
2768#a2# Only files with setgid/setuid/sticky flag
2769alias lss='ls -l *(s,S,t)'
2770#a2# Only show symlinks
2771alias lsl='ls -l *(@)'
2772#a2# Display only executables
2773alias lsx='ls -l *(*)'
2774#a2# Display world-{readable,writable,executable} files
2775alias lsw='ls -ld *(R,W,X.^ND/)'
2776#a2# Display the ten biggest files
2777alias lsbig="ls -flh *(.OL[1,10])"
2778#a2# Only show directories
2779alias lsd='ls -d *(/)'
2780#a2# Only show empty directories
2781alias lse='ls -d *(/^F)'
2782#a2# Display the ten newest files
2783alias lsnew="ls -rtlh *(D.om[1,10])"
2784#a2# Display the ten oldest files
2785alias lsold="ls -rtlh *(D.Om[1,10])"
2786#a2# Display the ten smallest files
2787alias lssmall="ls -Srl *(.oL[1,10])"
2788#a2# Display the ten newest directories and ten newest .directories
2789alias lsnewdir="ls -rthdl *(/om[1,10]) .*(D/om[1,10])"
2790#a2# Display the ten oldest directories and ten oldest .directories
2791alias lsolddir="ls -rthdl *(/Om[1,10]) .*(D/Om[1,10])"
2792
2793# some useful aliases
2794#a2# Remove current empty directory. Execute \kbd{cd ..; rmdir \$OLDCWD}
2795alias rmcdir='cd ..; rmdir $OLDPWD || cd $OLDPWD'
2796
2797#a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2798alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2799#a2# scp with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
2800alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
2801
2802# work around non utf8 capable software in utf environment via $LANG and luit
2803if check_com isutfenv && check_com luit ; then
2804 if check_com -c mrxvt ; then
2805 isutfenv && [[ -n "$LANG" ]] && \
2806 alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
2807 fi
2808
2809 if check_com -c aterm ; then
2810 isutfenv && [[ -n "$LANG" ]] && \
2811 alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
2812 fi
2813
2814 if check_com -c centericq ; then
2815 isutfenv && [[ -n "$LANG" ]] && \
2816 alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
2817 fi
2818fi
2819
2820# useful functions
2821
2822#f5# Backup \kbd{file {\rm to} file\_timestamp}
2823bk() {
2824 emulate -L zsh
2825 cp -b $1 $1_`date --iso-8601=m`
2826}
2827
2828#f5# cd to directoy and list files
2829cl() {
2830 emulate -L zsh
2831 cd $1 && ls -a
2832}
2833
2834# smart cd function, allows switching to /etc when running 'cd /etc/fstab'
2835cd() {
2836 if (( ${#argv} == 1 )) && [[ -f ${1} ]]; then
2837 [[ ! -e ${1:h} ]] && return 1
2838 print "Correcting ${1} to ${1:h}"
2839 builtin cd ${1:h}
2840 else
2841 builtin cd "$@"
2842 fi
2843}
2844
2845#f5# Create Directoy and \kbd{cd} to it
2846mkcd() {
2847 if (( ARGC != 1 )); then
2848 printf 'usage: mkcd <new-directory>\n'
2849 return 1;
2850 fi
2851 if [[ ! -d "$1" ]]; then
2852 command mkdir -p "$1"
2853 else
2854 printf '`%s'\'' already exists: cd-ing.\n' "$1"
2855 fi
2856 builtin cd "$1"
2857}
2858
2859#f5# Create temporary directory and \kbd{cd} to it
2860cdt() {
2861 local t
2862 t=$(mktemp -d)
2863 echo "$t"
2864 builtin cd "$t"
2865}
2866
2867#f5# List files which have been accessed within the last {\it n} days, {\it n} defaults to 1
2868accessed() {
2869 emulate -L zsh
2870 print -l -- *(a-${1:-1})
2871}
2872
2873#f5# List files which have been changed within the last {\it n} days, {\it n} defaults to 1
2874changed() {
2875 emulate -L zsh
2876 print -l -- *(c-${1:-1})
2877}
2878
2879#f5# List files which have been modified within the last {\it n} days, {\it n} defaults to 1
2880modified() {
2881 emulate -L zsh
2882 print -l -- *(m-${1:-1})
2883}
2884# modified() was named new() in earlier versions, add an alias for backwards compatibility
2885check_com new || alias new=modified
2886
2887# use colors when GNU grep with color-support
2888#a2# Execute \kbd{grep -{}-color=auto}
2889(( $#grep_options > 0 )) && alias grep='grep '${grep_options:+"${grep_options[*]}"}
2890
2891# Translate DE<=>EN
2892# 'translate' looks up fot a word in a file with language-to-language
2893# translations (field separator should be " : "). A typical wordlist looks
2894# like at follows:
2895# | english-word : german-transmission
2896# It's also only possible to translate english to german but not reciprocal.
2897# Use the following oneliner to turn back the sort order:
2898# $ awk -F ':' '{ print $2" : "$1" "$3 }' \
2899# /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
2900#f5# Translates a word
2901trans() {
2902 emulate -L zsh
2903 case "$1" in
2904 -[dD]*)
2905 translate -l de-en $2
2906 ;;
2907 -[eE]*)
2908 translate -l en-de $2
2909 ;;
2910 *)
2911 echo "Usage: $0 { -D | -E }"
2912 echo " -D == German to English"
2913 echo " -E == English to German"
2914 esac
2915}
2916
2917# Usage: simple-extract <file>
2918# Using option -d deletes the original archive file.
2919#f5# Smart archive extractor
2920simple-extract() {
2921 emulate -L zsh
2922 setopt extended_glob noclobber
2923 local DELETE_ORIGINAL DECOMP_CMD USES_STDIN USES_STDOUT GZTARGET WGET_CMD
2924 local RC=0
2925 zparseopts -D -E "d=DELETE_ORIGINAL"
2926 for ARCHIVE in "${@}"; do
2927 case $ARCHIVE in
2928 *(tar.bz2|tbz2|tbz))
2929 DECOMP_CMD="tar -xvjf -"
2930 USES_STDIN=true
2931 USES_STDOUT=false
2932 ;;
2933 *(tar.gz|tgz))
2934 DECOMP_CMD="tar -xvzf -"
2935 USES_STDIN=true
2936 USES_STDOUT=false
2937 ;;
2938 *(tar.xz|txz|tar.lzma))
2939 DECOMP_CMD="tar -xvJf -"
2940 USES_STDIN=true
2941 USES_STDOUT=false
2942 ;;
2943 *tar)
2944 DECOMP_CMD="tar -xvf -"
2945 USES_STDIN=true
2946 USES_STDOUT=false
2947 ;;
2948 *rar)
2949 DECOMP_CMD="unrar x"
2950 USES_STDIN=false
2951 USES_STDOUT=false
2952 ;;
2953 *lzh)
2954 DECOMP_CMD="lha x"
2955 USES_STDIN=false
2956 USES_STDOUT=false
2957 ;;
2958 *7z)
2959 DECOMP_CMD="7z x"
2960 USES_STDIN=false
2961 USES_STDOUT=false
2962 ;;
2963 *(zip|jar))
2964 DECOMP_CMD="unzip"
2965 USES_STDIN=false
2966 USES_STDOUT=false
2967 ;;
2968 *deb)
2969 DECOMP_CMD="ar -x"
2970 USES_STDIN=false
2971 USES_STDOUT=false
2972 ;;
2973 *bz2)
2974 DECOMP_CMD="bzip2 -d -c -"
2975 USES_STDIN=true
2976 USES_STDOUT=true
2977 ;;
2978 *(gz|Z))
2979 DECOMP_CMD="gzip -d -c -"
2980 USES_STDIN=true
2981 USES_STDOUT=true
2982 ;;
2983 *(xz|lzma))
2984 DECOMP_CMD="xz -d -c -"
2985 USES_STDIN=true
2986 USES_STDOUT=true
2987 ;;
2988 *)
2989 print "ERROR: '$ARCHIVE' has unrecognized archive type." >&2
2990 RC=$((RC+1))
2991 continue
2992 ;;
2993 esac
2994
2995 if ! check_com ${DECOMP_CMD[(w)1]}; then
2996 echo "ERROR: ${DECOMP_CMD[(w)1]} not installed." >&2
2997 RC=$((RC+2))
2998 continue
2999 fi
3000
3001 GZTARGET="${ARCHIVE:t:r}"
3002 if [[ -f $ARCHIVE ]] ; then
3003
3004 print "Extracting '$ARCHIVE' ..."
3005 if $USES_STDIN; then
3006 if $USES_STDOUT; then
3007 ${=DECOMP_CMD} < "$ARCHIVE" > $GZTARGET
3008 else
3009 ${=DECOMP_CMD} < "$ARCHIVE"
3010 fi
3011 else
3012 if $USES_STDOUT; then
3013 ${=DECOMP_CMD} "$ARCHIVE" > $GZTARGET
3014 else
3015 ${=DECOMP_CMD} "$ARCHIVE"
3016 fi
3017 fi
3018 [[ $? -eq 0 && -n "$DELETE_ORIGINAL" ]] && rm -f "$ARCHIVE"
3019
3020 elif [[ "$ARCHIVE" == (#s)(https|http|ftp)://* ]] ; then
3021 if check_com curl; then
3022 WGET_CMD="curl -L -k -s -o -"
3023 elif check_com wget; then
3024 WGET_CMD="wget -q -O - --no-check-certificate"
3025 else
3026 print "ERROR: neither wget nor curl is installed" >&2
3027 RC=$((RC+4))
3028 continue
3029 fi
3030 print "Downloading and Extracting '$ARCHIVE' ..."
3031 if $USES_STDIN; then
3032 if $USES_STDOUT; then
3033 ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD} > $GZTARGET
3034 RC=$((RC+$?))
3035 else
3036 ${=WGET_CMD} "$ARCHIVE" | ${=DECOMP_CMD}
3037 RC=$((RC+$?))
3038 fi
3039 else
3040 if $USES_STDOUT; then
3041 ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE") > $GZTARGET
3042 else
3043 ${=DECOMP_CMD} =(${=WGET_CMD} "$ARCHIVE")
3044 fi
3045 fi
3046
3047 else
3048 print "ERROR: '$ARCHIVE' is neither a valid file nor a supported URI." >&2
3049 RC=$((RC+8))
3050 fi
3051 done
3052 return $RC
3053}
3054
3055__archive_or_uri()
3056{
3057 _alternative \
3058 'files:Archives:_files -g "*.(#l)(tar.bz2|tbz2|tbz|tar.gz|tgz|tar.xz|txz|tar.lzma|tar|rar|lzh|7z|zip|jar|deb|bz2|gz|Z|xz|lzma)"' \
3059 '_urls:Remote Archives:_urls'
3060}
3061
3062_simple_extract()
3063{
3064 _arguments \
3065 '-d[delete original archivefile after extraction]' \
3066 '*:Archive Or Uri:__archive_or_uri'
3067}
3068compdef _simple_extract simple-extract
3069alias se=simple-extract
3070
3071#f5# Set all ulimit parameters to \kbd{unlimited}
3072allulimit() {
3073 ulimit -c unlimited
3074 ulimit -d unlimited
3075 ulimit -f unlimited
3076 ulimit -l unlimited
3077 ulimit -n unlimited
3078 ulimit -s unlimited
3079 ulimit -t unlimited
3080}
3081
3082#f5# Change the xterm title from within GNU-screen
3083xtrename() {
3084 emulate -L zsh
3085 if [[ $1 != "-f" ]] ; then
3086 if [[ -z ${DISPLAY} ]] ; then
3087 printf 'xtrename only makes sense in X11.\n'
3088 return 1
3089 fi
3090 else
3091 shift
3092 fi
3093 if [[ -z $1 ]] ; then
3094 printf 'usage: xtrename [-f] "title for xterm"\n'
3095 printf ' renames the title of xterm from _within_ screen.\n'
3096 printf ' also works without screen.\n'
3097 printf ' will not work if DISPLAY is unset, use -f to override.\n'
3098 return 0
3099 fi
3100 print -n "\eP\e]0;${1}\C-G\e\\"
3101 return 0
3102}
3103
3104# Create small urls via http://goo.gl using curl(1).
3105# API reference: https://code.google.com/apis/urlshortener/
3106function zurl() {
3107 emulate -L zsh
3108 setopt extended_glob
3109
3110 if [[ -z $1 ]]; then
3111 print "USAGE: zurl <URL>"
3112 return 1
3113 fi
3114
3115 local PN url prog api json contenttype item
3116 local -a data
3117 PN=$0
3118 url=$1
3119
3120 # Prepend 'http://' to given URL where necessary for later output.
3121 if [[ ${url} != http(s|)://* ]]; then
3122 url='http://'${url}
3123 fi
3124
3125 if check_com -c curl; then
3126 prog=curl
3127 else
3128 print "curl is not available, but mandatory for ${PN}. Aborting."
3129 return 1
3130 fi
3131 api='https://www.googleapis.com/urlshortener/v1/url'
3132 contenttype="Content-Type: application/json"
3133 json="{\"longUrl\": \"${url}\"}"
3134 data=(${(f)"$($prog --silent -H ${contenttype} -d ${json} $api)"})
3135 # Parse the response
3136 for item in "${data[@]}"; do
3137 case "$item" in
3138 ' '#'"id":'*)
3139 item=${item#*: \"}
3140 item=${item%\",*}
3141 printf '%s\n' "$item"
3142 return 0
3143 ;;
3144 esac
3145 done
3146 return 1
3147}
3148
3149#f2# Find history events by search pattern and list them by date.
3150whatwhen() {
3151 emulate -L zsh
3152 local usage help ident format_l format_s first_char remain first last
3153 usage='USAGE: whatwhen [options] <searchstring> <search range>'
3154 help='Use `whatwhen -h'\'' for further explanations.'
3155 ident=${(l,${#${:-Usage: }},, ,)}
3156 format_l="${ident}%s\t\t\t%s\n"
3157 format_s="${format_l//(\\t)##/\\t}"
3158 # Make the first char of the word to search for case
3159 # insensitive; e.g. [aA]
3160 first_char=[${(L)1[1]}${(U)1[1]}]
3161 remain=${1[2,-1]}
3162 # Default search range is `-100'.
3163 first=${2:-\-100}
3164 # Optional, just used for `<first> <last>' given.
3165 last=$3
3166 case $1 in
3167 ("")
3168 printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
3169 printf '%s\n%s\n\n' ${usage} ${help} && return 1
3170 ;;
3171 (-h)
3172 printf '%s\n\n' ${usage}
3173 print 'OPTIONS:'
3174 printf $format_l '-h' 'show help text'
3175 print '\f'
3176 print 'SEARCH RANGE:'
3177 printf $format_l "'0'" 'the whole history,'
3178 printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
3179 printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
3180 printf '\n%s\n' 'EXAMPLES:'
3181 printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
3182 printf $format_l 'whatwhen zsh -250'
3183 printf $format_l 'whatwhen foo 1 99'
3184 ;;
3185 (\?)
3186 printf '%s\n%s\n\n' ${usage} ${help} && return 1
3187 ;;
3188 (*)
3189 # -l list results on stout rather than invoking $EDITOR.
3190 # -i Print dates as in YYYY-MM-DD.
3191 # -m Search for a - quoted - pattern within the history.
3192 fc -li -m "*${first_char}${remain}*" $first $last
3193 ;;
3194 esac
3195}
3196
3197# mercurial related stuff
3198if check_com -c hg ; then
3199 # gnu like diff for mercurial
3200 # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
3201 #f5# GNU like diff for mercurial
3202 hgdi() {
3203 emulate -L zsh
3204 for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
3205 }
3206
3207 # build debian package
3208 #a2# Alias for \kbd{hg-buildpackage}
3209 alias hbp='hg-buildpackage'
3210
3211 # execute commands on the versioned patch-queue from the current repos
3212 alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
3213
3214 # diffstat for specific version of a mercurial repository
3215 # hgstat => display diffstat between last revision and tip
3216 # hgstat 1234 => display diffstat between revision 1234 and tip
3217 #f5# Diffstat for specific version of a mercurial repos
3218 hgstat() {
3219 emulate -L zsh
3220 [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
3221 }
3222
3223fi # end of check whether we have the 'hg'-executable
3224
3225# grml-small cleanups
3226
3227# The following is used to remove zsh-config-items that do not work
3228# in grml-small by default.
3229# If you do not want these adjustments (for whatever reason), set
3230# $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
3231# sources if it is there).
3232
3233if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
3234
3235 unset abk[V]
3236 unalias 'V' &> /dev/null
3237 unfunction vman &> /dev/null
3238 unfunction viless &> /dev/null
3239 unfunction 2html &> /dev/null
3240
3241 # manpages are not in grmlsmall
3242 unfunction manzsh &> /dev/null
3243 unfunction man2 &> /dev/null
3244
3245fi
3246
3247zrclocal
3248
3249## genrefcard.pl settings
3250
3251### doc strings for external functions from files
3252#m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
3253
3254### example: split functions-search 8,16,24,32
3255#@# split functions-search 8
3256
3257## END OF FILE #################################################################
3258# vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4
3259# Local variables:
3260# mode: sh
3261# End: